2 files changed, 0 insertions, 100 deletions
diff --git a/sci-libs/ceres-solver/Manifest b/sci-libs/ceres-solver/Manifest
index 8d35692a2766..c3da8e66ac75 100644
--- a/sci-libs/ceres-solver/Manifest
+++ b/sci-libs/ceres-solver/Manifest
@@ -1,2 +1 @@
-DIST ceres-solver-2.0.0.tar.gz 11225245 BLAKE2B 1761908747d460f6a84cb519b4bbb49fec7e1e36cc616b438c45ace57d10bd3bb4d0cb2795e07d5096e0b9453511c185ffdd3872e317aa8095daeb86933643b0 SHA512 843b19389f4d628b2b8b8538655cb330e092ffcc960c6896c6e3065b3a34e330c81e993b7abcd754e575742e2104087efde3526945c92f7df3f6b700984e49f9
 DIST ceres-solver-2.1.0.tar.gz 3802187 BLAKE2B d8ff780cf9b9de2541c15a2b95bde07a2d1c8e60bab3a8a4b13134b99da699da452467afe3310b9f70c3c2a6bd033ea3c4bd3c401153899e9c70867fae30c633 SHA512 db777c4a4b85a9972628c714413fe9ca1a92cc6c8b14d80401842a02c4d7e7df4e9d236775e231e8337e47f21e47cd82c1a0fbcfeffbd9b654e46a66262996f2
diff --git a/sci-libs/ceres-solver/ceres-solver-2.0.0.ebuild b/sci-libs/ceres-solver/ceres-solver-2.0.0.ebuild
deleted file mode 100644
index 684d229cf029..000000000000
--- a/sci-libs/ceres-solver/ceres-solver-2.0.0.ebuild
+++ /dev/null
@@ -1,99 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{8..10} )
-DOCS_BUILDER="sphinx"
-DOCS_DEPEND="dev-python/sphinx_rtd_theme"
-DOCS_DIR="docs/source"
-inherit cmake-multilib python-any-r1 docs toolchain-funcs
-
-DESCRIPTION="Nonlinear least-squares minimizer"
-HOMEPAGE="http://ceres-solver.org/"
-SRC_URI="http://ceres-solver.org/${P}.tar.gz"
-
-LICENSE="sparse? ( BSD ) !sparse? ( LGPL-2.1 ) cxsparse? ( BSD )"
-SLOT="0/1"
-KEYWORDS="amd64 ~x86 ~amd64-linux ~x86-linux"
-IUSE="cxsparse examples gflags lapack openmp +schur sparse test"
-
-REQUIRED_USE="test? ( gflags ) sparse? ( lapack ) abi_x86_32? ( !sparse !lapack )"
-
-RESTRICT="!test? ( test )"
-
-BDEPEND="${PYTHON_DEPS}
-	>=dev-cpp/eigen-3.3.4:3
-	lapack? ( virtual/pkgconfig )
-	doc? ( dev-libs/mathjax )
-"
-RDEPEND="
-	dev-cpp/glog[gflags?,${MULTILIB_USEDEP}]
-	cxsparse? ( sci-libs/cxsparse )
-	lapack? ( virtual/lapack )
-	sparse? (
-		sci-libs/amd
-		sci-libs/camd
-		sci-libs/ccolamd
-		sci-libs/cholmod[metis(+)]
-		sci-libs/colamd
-		sci-libs/spqr
-	)
-"
-DEPEND="${RDEPEND}"
-
-DOCS=( README.md VERSION )
-
-PATCHES=( "${FILESDIR}/${P}-system-mathjax.patch" )
-
-pkg_pretend() {
-	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
-}
-
-pkg_setup() {
-	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
-	use doc && python-any-r1_pkg_setup
-}
-
-src_prepare() {
-	cmake_src_prepare
-
-	# search paths work for prefix
-	sed -e "s:/usr:${EPREFIX}/usr:g" \
-		-i cmake/*.cmake || die
-
-	# remove Werror
-	sed -e 's/-Werror=(all|extra)//g' \
-		-i CMakeLists.txt || die
-}
-
-src_configure() {
-	# CUSTOM_BLAS=OFF EIGENSPARSE=OFF MINIGLOG=OFF CXX11=OFF
-	local mycmakeargs=(
-		-DBUILD_BENCHMARKS=OFF
-		-DBUILD_EXAMPLES=$(usex examples)
-		-DBUILD_TESTING=$(usex test)
-		-DBUILD_DOCUMENTATION=$(usex doc)
-		-DGFLAGS=$(usex gflags)
-		-DLAPACK=$(usex lapack)
-		-DSCHUR_SPECIALIZATIONS=$(usex schur)
-		-DCXSPARSE=$(usex cxsparse)
-		-DSUITESPARSE=$(usex sparse)
-		-DEigen3_DIR=/usr/$(get_libdir)/cmake/eigen3
-		-DCERES_THREADING_MODEL=$(usex openmp OPENMP CXX_THREADS)
-	)
-	use doc && mycmakeargs+=(
-		-DCERES_DOCS_INSTALL_DIR="${EPREFIX}"/usr/share/doc/${PF}
-	)
-	use sparse || use cxsparse || mycmakeargs+=( -DEIGENSPARSE=ON )
-	cmake-multilib_src_configure
-}
-
-src_install() {
-	cmake-multilib_src_install
-
-	if use examples; then
-		docompress -x /usr/share/doc/${PF}/examples
-		dodoc -r examples data
-	fi
-}