1 files changed, 67 insertions, 0 deletions
diff --git a/sci-physics/fastjet/fastjet-3.0.6-r3.ebuild b/sci-physics/fastjet/fastjet-3.0.6-r3.ebuild
new file mode 100644
index 000000000000..083818379ede
--- /dev/null
+++ b/sci-physics/fastjet/fastjet-3.0.6-r3.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+FORTRAN_NEEDED=plugins
+
+inherit autotools flag-o-matic fortran-2
+
+DESCRIPTION="Fast implementation of several recombination jet algorithms"
+HOMEPAGE="http://www.fastjet.fr/"
+SRC_URI="http://www.fastjet.fr/repo/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="cgal doc examples +plugins"
+
+RDEPEND="
+	cgal? ( sci-mathematics/cgal:=[shared(+)] )
+	plugins? ( sci-physics/siscone:= )"
+DEPEND="${RDEPEND}"
+BDEPEND="doc? ( app-doc/doxygen[dot] )"
+
+PATCHES=( "${FILESDIR}"/${P}-system-siscone.patch )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	use cgal && \
+		has_version 'sci-mathematics/cgal[gmp]' && append-libs -lgmp
+
+	CONFIG_SHELL="${EPREFIX}/bin/bash" \
+	econf \
+		--disable-static \
+		$(use_enable cgal) \
+		$(use_enable plugins allplugins) \
+		$(use_enable plugins allcxxplugins)
+}
+
+src_compile() {
+	default
+
+	if use doc; then
+		doxygen Doxyfile || die
+		HTML_DOCS=( html/. )
+	fi
+}
+
+src_install() {
+	default
+
+	if use examples; then
+		emake -C example maintainer-clean
+		find example -iname 'makefile*' -delete || die
+
+		docinto examples
+		dodoc -r example/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	# no static archives
+	find "${ED}" -name '*.la' -delete || die
+}