1 files changed, 38 insertions, 0 deletions
diff --git a/sys-apps/nvme-cli/nvme-cli-2.0-r1.ebuild b/sys-apps/nvme-cli/nvme-cli-2.0-r1.ebuild
new file mode 100644
index 000000000000..bc3e02e3f368
--- /dev/null
+++ b/sys-apps/nvme-cli/nvme-cli-2.0-r1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson systemd udev
+
+DESCRIPTION="NVM-Express user space tooling for Linux"
+HOMEPAGE="https://github.com/linux-nvme/nvme-cli"
+SRC_URI="https://github.com/linux-nvme/nvme-cli/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+RESTRICT="test"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="hugepages +json +uuid"
+
+RDEPEND="
+	sys-libs/libnvme:=[json=,uuid=]
+	hugepages? ( sys-libs/libhugetlbfs:= )
+	json? ( dev-libs/json-c:= )
+	uuid? ( sys-apps/util-linux:= )"
+
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-bash-completions.patch # Gentoo bug #852764
+)
+
+src_configure() {
+	local unitdir="$(systemd_get_systemunitdir)"
+	local emesonargs=(
+		-Dsystemddir=${unitdir%/system}
+		-Dudevrulesdir=${EPREFIX}$(get_udevdir)
+	)
+	meson_src_configure
+}