1 files changed, 60 insertions, 0 deletions
diff --git a/sys-cluster/galera/galera-26.4.15.ebuild b/sys-cluster/galera/galera-26.4.15.ebuild
new file mode 100644
index 000000000000..0593b2770b14
--- /dev/null
+++ b/sys-cluster/galera/galera-26.4.15.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+MY_PN="${PN}-4"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Synchronous multi-master replication engine that provides the wsrep API"
+HOMEPAGE="https://galeracluster.com"
+SRC_URI="https://releases.galeracluster.com/${MY_PN}/source/${MY_P}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-2 BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~x86"
+IUSE="garbd test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/openssl:=
+	dev-libs/boost:=
+"
+DEPEND="
+	${RDEPEND}
+	>=dev-cpp/asio-1.22
+	test? ( dev-libs/check )
+"
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Remove bundled dev-cpp/asio
+	rm -r asio || die "Failed to remove bundled asio"
+
+	# Remove optional garbd daemon
+	if ! use garbd ; then
+		rm -r garb || die "Failed to remove garbd daemon"
+		sed -i '/add_subdirectory(garb)/d' CMakeLists.txt || die
+	fi
+}
+
+src_install() {
+	dodoc scripts/packages/README scripts/packages/README-MySQL
+
+	if use garbd ; then
+		newconfd "${FILESDIR}"/garb.cnf garbd
+		newinitd "${FILESDIR}"/garb.init garbd
+		doman man/garbd.8
+
+		pushd "${BUILD_DIR}" || die
+		dobin garb/garbd
+	fi
+
+	pushd "${BUILD_DIR}" || die
+	exeinto /usr/$(get_libdir)/galera
+	doexe libgalera_smm.so
+}