7 files changed, 77 insertions, 66 deletions
diff --git a/www-apps/prowlarr/Manifest b/www-apps/prowlarr-bin/Manifest
index 63d2b0e057e8..63d2b0e057e8 100644
--- a/www-apps/prowlarr/Manifest
+++ b/www-apps/prowlarr-bin/Manifest
diff --git a/www-apps/prowlarr/files/prowlarr.init b/www-apps/prowlarr-bin/files/prowlarr.init
index 831a4425a80a..831a4425a80a 100644
--- a/www-apps/prowlarr/files/prowlarr.init
+++ b/www-apps/prowlarr-bin/files/prowlarr.init
diff --git a/www-apps/prowlarr/files/prowlarr.logrotate b/www-apps/prowlarr-bin/files/prowlarr.logrotate
index 32f121fb6378..32f121fb6378 100644
--- a/www-apps/prowlarr/files/prowlarr.logrotate
+++ b/www-apps/prowlarr-bin/files/prowlarr.logrotate
diff --git a/www-apps/prowlarr/files/prowlarr.service b/www-apps/prowlarr-bin/files/prowlarr.service
index 7fe9097bf338..7fe9097bf338 100644
--- a/www-apps/prowlarr/files/prowlarr.service
+++ b/www-apps/prowlarr-bin/files/prowlarr.service
diff --git a/www-apps/prowlarr/metadata.xml b/www-apps/prowlarr-bin/metadata.xml
index 590d0e5c4cf8..590d0e5c4cf8 100644
--- a/www-apps/prowlarr/metadata.xml
+++ b/www-apps/prowlarr-bin/metadata.xml
diff --git a/www-apps/prowlarr-bin/prowlarr-bin-1.14.3.4333.ebuild b/www-apps/prowlarr-bin/prowlarr-bin-1.14.3.4333.ebuild
new file mode 100644
index 000000000000..2c9c3707ba6b
--- /dev/null
+++ b/www-apps/prowlarr-bin/prowlarr-bin-1.14.3.4333.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit systemd
+
+DESCRIPTION="An indexer manager/proxy to integrate with your various PVR apps"
+HOMEPAGE="https://wiki.servarr.com/prowlarr/
+	https://github.com/Prowlarr/Prowlarr/"
+
+SRC_URI="
+	amd64? (
+		elibc_glibc? (
+			https://github.com/Prowlarr/Prowlarr/releases/download/v${PV}/Prowlarr.master.${PV}.linux-core-x64.tar.gz
+		)
+		elibc_musl? (
+			https://github.com/Prowlarr/Prowlarr/releases/download/v${PV}/Prowlarr.master.${PV}.linux-musl-core-x64.tar.gz
+		)
+	)
+	arm? (
+		elibc_glibc? (
+			https://github.com/Prowlarr/Prowlarr/releases/download/v${PV}/Prowlarr.master.${PV}.linux-core-arm.tar.gz
+		)
+		elibc_musl? (
+			https://github.com/Prowlarr/Prowlarr/releases/download/v${PV}/Prowlarr.master.${PV}.linux-musl-core-arm.tar.gz
+		)
+	)
+	arm64? (
+		elibc_glibc? (
+			https://github.com/Prowlarr/Prowlarr/releases/download/v${PV}/Prowlarr.master.${PV}.linux-core-arm64.tar.gz
+		)
+		elibc_musl? (
+			https://github.com/Prowlarr/Prowlarr/releases/download/v${PV}/Prowlarr.master.${PV}.linux-musl-core-arm64.tar.gz
+		)
+	)
+"
+S="${WORKDIR}/Prowlarr"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~arm ~arm64"
+RESTRICT="bindist strip test"
+
+RDEPEND="
+	acct-group/prowlarr
+	acct-user/prowlarr
+	dev-libs/icu
+	dev-util/lttng-ust:0
+	dev-db/sqlite
+"
+
+QA_PREBUILT="*"
+
+src_prepare() {
+	default
+
+	# https://github.com/dotnet/runtime/issues/57784
+	rm libcoreclrtraceptprovider.so Prowlarr.Update/libcoreclrtraceptprovider.so || die
+}
+
+src_install() {
+	newinitd "${FILESDIR}/prowlarr.init" prowlarr
+
+	keepdir /var/lib/prowlarr
+	fowners -R prowlarr:prowlarr /var/lib/prowlarr
+
+	insinto /etc/logrotate.d
+	insopts -m0644 -o root -g root
+	newins "${FILESDIR}/prowlarr.logrotate" prowlarr
+
+	dodir  "/opt/prowlarr"
+	cp -R "${S}/." "${D}/opt/prowlarr" || die "Install failed!"
+
+	systemd_dounit "${FILESDIR}/prowlarr.service"
+	systemd_newunit "${FILESDIR}/prowlarr.service" "prowlarr@.service"
+}
diff --git a/www-apps/prowlarr/prowlarr-1.14.3.4333.ebuild b/www-apps/prowlarr/prowlarr-1.14.3.4333.ebuild
deleted file mode 100644
index 7661310592fb..000000000000
--- a/www-apps/prowlarr/prowlarr-1.14.3.4333.ebuild
+++ /dev/null
@@ -1,66 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit systemd
-
-SRC_URI="
-	amd64? (
-		elibc_glibc? ( https://github.com/Prowlarr/Prowlarr/releases/download/v${PV}/Prowlarr.master.${PV}.linux-core-x64.tar.gz )
-		elibc_musl? ( https://github.com/Prowlarr/Prowlarr/releases/download/v${PV}/Prowlarr.master.${PV}.linux-musl-core-x64.tar.gz )
-	)
-	arm? (
-		elibc_glibc? ( https://github.com/Prowlarr/Prowlarr/releases/download/v${PV}/Prowlarr.master.${PV}.linux-core-arm.tar.gz )
-		elibc_musl? ( https://github.com/Prowlarr/Prowlarr/releases/download/v${PV}/Prowlarr.master.${PV}.linux-musl-core-arm.tar.gz )
-	)
-	arm64? (
-		elibc_glibc? ( https://github.com/Prowlarr/Prowlarr/releases/download/v${PV}/Prowlarr.master.${PV}.linux-core-arm64.tar.gz )
-		elibc_musl? ( https://github.com/Prowlarr/Prowlarr/releases/download/v${PV}/Prowlarr.master.${PV}.linux-musl-core-arm64.tar.gz )
-	)
-"
-
-DESCRIPTION="An indexer manager/proxy to integrate with your various PVR apps"
-HOMEPAGE="https://wiki.servarr.com/prowlarr"
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="-* ~amd64 ~arm ~arm64"
-RESTRICT="bindist strip test"
-
-RDEPEND="
-	acct-group/prowlarr
-	acct-user/prowlarr
-	dev-libs/icu
-	dev-util/lttng-ust:0
-	dev-db/sqlite
-	sys-libs/glibc
-"
-
-QA_PREBUILT="*"
-
-S="${WORKDIR}/Prowlarr"
-
-src_prepare() {
-	default
-
-	# https://github.com/dotnet/runtime/issues/57784
-	rm libcoreclrtraceptprovider.so Prowlarr.Update/libcoreclrtraceptprovider.so || die
-}
-
-src_install() {
-	newinitd "${FILESDIR}/${PN}.init" ${PN}
-
-	keepdir /var/lib/${PN}
-	fowners -R ${PN}:${PN} /var/lib/${PN}
-
-	insinto /etc/logrotate.d
-	insopts -m0644 -o root -g root
-	newins "${FILESDIR}/${PN}.logrotate" ${PN}
-
-	dodir  "/opt/${PN}"
-	cp -R "${S}/." "${D}/opt/prowlarr" || die "Install failed!"
-
-	systemd_dounit "${FILESDIR}/prowlarr.service"
-	systemd_newunit "${FILESDIR}/prowlarr.service" "${PN}@.service"
-}