1 files changed, 49 insertions, 0 deletions
diff --git a/x11-misc/menumaker/menumaker-0.99.14.ebuild b/x11-misc/menumaker/menumaker-0.99.14.ebuild
new file mode 100644
index 000000000000..adea47767a3c
--- /dev/null
+++ b/x11-misc/menumaker/menumaker-0.99.14.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit autotools python-single-r1
+
+DESCRIPTION="Utility that scans through the system and generates a menu of installed programs"
+HOMEPAGE="http://menumaker.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 ~ppc x86"
+
+IUSE="doc"
+
+RDEPEND="${PYTHON_DEPS}"
+DEPEND="${RDEPEND}
+	doc? ( sys-apps/texinfo )"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.99.12-AM_PATH_PYTHON.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	ECONF_SOURCE="${S}" econf PYTHON="${EPYTHON}"
+}
+
+src_compile() {
+	default
+	use doc && emake html
+}
+
+src_install() {
+	default
+	use doc && emake DESTDIR="${D}" install-html
+	python_optimize
+	python_fix_shebang "${ED}"/usr/bin/mmaker
+}