1 files changed, 51 insertions, 0 deletions
diff --git a/x11-misc/nitrogen/nitrogen-1.6.1.ebuild b/x11-misc/nitrogen/nitrogen-1.6.1.ebuild
new file mode 100644
index 000000000000..ad60240a2591
--- /dev/null
+++ b/x11-misc/nitrogen/nitrogen-1.6.1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit autotools fdo-mime flag-o-matic
+
+DESCRIPTION="A background browser and setter for X"
+HOMEPAGE="http://projects.l3ib.org/nitrogen/"
+SRC_URI="http://projects.l3ib.org/${PN}/files/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nls xinerama"
+
+RDEPEND="
+	>=dev-cpp/gtkmm-2.10:2.4
+	>=gnome-base/librsvg-2.20:2
+	>=x11-libs/gtk+-2.10:2
+	xinerama? ( x11-libs/libXinerama )
+"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+	xinerama? ( x11-proto/xineramaproto )
+"
+
+src_prepare() {
+	default
+
+	sed -i -e '/^UPDATE_DESKTOP/s#=.*#= :#g' data/Makefile.am || die
+
+	eautoreconf
+}
+
+src_configure() {
+	append-cxxflags -std=c++11
+	econf \
+		$(use_enable nls) \
+		$(use_enable xinerama)
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+}