1 files changed, 47 insertions, 0 deletions
diff --git a/x11-plugins/purple-hangouts/purple-hangouts-0_p20200710.ebuild b/x11-plugins/purple-hangouts/purple-hangouts-0_p20200710.ebuild
new file mode 100644
index 000000000000..f461413cc277
--- /dev/null
+++ b/x11-plugins/purple-hangouts/purple-hangouts-0_p20200710.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="Hangouts Plugin for libpurple"
+HOMEPAGE="https://github.com/EionRobb/purple-hangouts"
+
+COMMIT_ID="efa7a53e2db4087a1590850423aa16b380bfbbd5"
+SRC_URI="https://github.com/EionRobb/purple-hangouts/archive/${COMMIT_ID}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${COMMIT_ID}"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/protobuf-c:=
+	net-im/pidgin
+	sys-libs/zlib"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	# Does not respect CFLAGS
+	sed -i Makefile -e 's/-g -ggdb//g' || die
+}
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		PKG_CONFIG="$(tc-getPKG_CONFIG)"
+}
+
+src_install() {
+	emake \
+		PKG_CONFIG="$(tc-getPKG_CONFIG)" \
+		DESTDIR="${ED}" \
+		install
+
+	einstalldocs
+}