blob: b921679f6f1bf6c0c8d8e67d171fdb905a969220 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
|
# Copyright 1999-2018 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit eutils multilib user systemd toolchain-funcs
MY_P="${P/_/-}"
DESCRIPTION="Single process stack of various system monitors"
HOMEPAGE="http://www.gkrellm.net/"
# Upstream named their xz compressed tarball tar.bz2 (*sigh*)
SRC_URI="http://gkrellm.srcbox.net/${MY_P}.tar.bz2"
LICENSE="GPL-3"
SLOT="2"
KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 sparc x86 ~x86-fbsd ~amd64-linux ~x86-linux"
IUSE="gnutls hddtemp libressl lm_sensors nls ntlm ssl kernel_FreeBSD X"
RDEPEND="
dev-libs/glib:2
hddtemp? ( app-admin/hddtemp )
ssl? (
gnutls? ( net-libs/gnutls )
!gnutls? (
!libressl? ( dev-libs/openssl:0= )
libressl? ( dev-libs/libressl:0= )
)
)
lm_sensors? ( sys-apps/lm_sensors )
nls? ( virtual/libintl )
ntlm? ( net-libs/libntlm )
X? (
x11-libs/gdk-pixbuf
x11-libs/gtk+:2
x11-libs/libICE
x11-libs/libSM
x11-libs/libX11
x11-libs/pango
)"
DEPEND="${RDEPEND}
virtual/pkgconfig
nls? ( sys-devel/gettext )"
PATCHES=(
"${FILESDIR}"/${PN}-2.3.5-cifs.patch
"${FILESDIR}"/${PN}-2.3.5-config.patch
"${FILESDIR}"/${PN}-2.3.5-width.patch
"${FILESDIR}"/${PN}-2.3.5-sansfont.patch
)
S="${WORKDIR}/${MY_P}"
DOCS=( Changelog CREDITS README )
pkg_pretend() {
if use gnutls && ! use ssl ; then
ewarn "You have enabled the \"gnutls\" USE flag but not the \"ssl\" USE flag."
ewarn "No ssl backend will be built!"
fi
}
pkg_setup() {
enewgroup gkrellmd
enewuser gkrellmd -1 -1 -1 gkrellmd
TARGET=
use kernel_FreeBSD && TARGET="freebsd"
}
src_prepare() {
sed -e 's:-O2 ::' \
-e 's:override CC:CFLAGS:' \
-e 's:-L/usr/X11R6/lib::' \
-i */Makefile || die "sed Makefile(s) failed"
sed -e "s:/usr/lib:${EPREFIX}/usr/$(get_libdir):" \
-e "s:/usr/local/lib:${EPREFIX}/usr/local/$(get_libdir):" \
-i src/${PN}.h || die "sed ${PN}.h failed"
default
}
src_compile() {
if use X ; then
emake \
${TARGET} \
CC="$(tc-getCC)" \
STRIP="" \
INSTALLROOT="${EPREFIX}/usr" \
INCLUDEDIR="${EPREFIX}/usr/include/gkrellm2" \
LOCALEDIR="${EPREFIX}/usr/share/locale" \
$(usex nls "" "enable_nls=0") \
$(usex lm_sensors "" "without-libsensors=yes") \
$(usex ntlm "" "without-ntlm=yes") \
$(usex ssl $(usex gnutls 'without-ssl=yes' 'without-gnutls=yes') 'without-ssl=yes without-gnutls=yes')
else
cd server || die
emake \
${TARGET} \
CC="$(tc-getCC)" \
LINK_FLAGS="$LDFLAGS -Wl,-E" \
STRIP="" \
$(usex nls "" "enable_nls=0") \
$(usex lm_sensors "" "without-libsensors=yes")
fi
}
src_install() {
if use X ; then
emake \
install${TARGET:+_}${TARGET} \
$(usex nls "" "enable_nls=0") \
STRIP="" \
INSTALLDIR="${ED}/usr/bin" \
INCLUDEDIR="${ED}/usr/include" \
LOCALEDIR="${ED}/usr/share/locale" \
PKGCONFIGDIR="${ED}/usr/$(get_libdir)/pkgconfig" \
MANDIR="${ED}/usr/share/man/man1"
docinto html
dodoc *.html
newicon src/icon.xpm ${PN}.xpm
make_desktop_entry ${PN} GKrellM ${PN}
else
dobin server/gkrellmd
insinto /usr/include/gkrellm2
doins server/gkrellmd.h
doins shared/log.h
fi
newinitd "${FILESDIR}"/gkrellmd.initd gkrellmd
newconfd "${FILESDIR}"/gkrellmd.conf gkrellmd
systemd_dounit "${FILESDIR}"/gkrellmd.service
insinto /etc
doins server/gkrellmd.conf
einstalldocs
}
|
GitWeb