blob: 5e4745ea5cab250a67411aee5ef0a61bcad989db (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools
MY_PV="${PV/_/-}"
DESCRIPTION="file integrity verification program"
HOMEPAGE="http://integrit.sourceforge.net/"
SRC_URI="https://github.com/integrit/integrit/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""
# Tests don't work in 4.2_rc1. Please re-check on version bump!
RESTRICT="test"
S="${WORKDIR}/${PN}-${MY_PV}"
PATCHES=( "${FILESDIR}"/${PN}-4.1-fix-build-system.patch )
src_prepare() {
default
mv configure.{in,ac} || die
mv hashtbl/configure.{in,ac} || die
eautoreconf
touch ar-lib || die #775746
}
src_compile() {
emake
emake utils
emake -C doc
emake -C hashtbl hashtest
}
src_install() {
dosbin integrit
dolib.a libintegrit.a
dodoc Changes HACKING README todo.txt
# utils
dosbin utils/i-viewdb
dobin utils/i-ls
# hashtbl
dolib.a hashtbl/libhashtbl.a
doheader hashtbl/hashtbl.h
dobin hashtbl/hashtest
newdoc hashtbl/README README.hashtbl
# doc
doman doc/{i-ls.1,i-viewdb.1,integrit.1}
doinfo doc/integrit.info
# examples
dodoc -r examples
}
pkg_postinst() {
elog "It is recommended that the integrit binary is copied to a secure"
elog "location and re-copied at runtime or run from a secure medium."
elog "You should also create a configuration file (see examples)."
}
|
GitWeb
