blob: fcb4a4ab3809806688773f8a2e6adaff2af4b898 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit eutils toolchain-funcs
DESCRIPTION="Tools for manipulating signed PE-COFF binaries"
HOMEPAGE="https://github.com/rhboot/pesign"
SRC_URI="https://github.com/rhboot/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="libressl"
RDEPEND="
dev-libs/nspr
dev-libs/nss
dev-libs/popt
!libressl? ( dev-libs/openssl:0= )
libressl? ( dev-libs/libressl:0= )
sys-apps/util-linux
sys-libs/efivar
"
DEPEND="${RDEPEND}
sys-apps/help2man
sys-boot/gnu-efi
virtual/pkgconfig
"
PATCHES=( "${FILESDIR}"/${PN}-113-nss.patch )
src_compile() {
emake AR="$(tc-getAR)" \
ARFLAGS="-cvqs" \
AS="$(tc-getAS)" \
CC="$(tc-getCC)" \
LD="$(tc-getLD)" \
OBJCOPY="$(tc-getOBJCOPY)" \
PKG_CONFIG="$(tc-getPKG_CONFIG)" \
RANLIB="$(tc-getRANLIB)"
}
src_install() {
emake DESTDIR="${ED}" VERSION="${PVR}" install
einstalldocs
# remove some files that don't make sense for Gentoo installs
rm -rf "${ED%/}/etc/" "${ED%/}/var/" \
"${ED%/}/usr/share/doc/${PF}/COPYING" || die
}
|
GitWeb
