app-emacs/julia-repl/julia-repl-1.3.0_p20220225.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

H=6c1d63511fb2b3b3f2e342eff6a375d78be6c12c
NEED_EMACS=25.1

inherit optfeature elisp

DESCRIPTION="Run an inferior Julia REPL in a terminal inside Emacs"
HOMEPAGE="https://github.com/tpapp/julia-repl/"
SRC_URI="https://github.com/tpapp/${PN}/archive/${H}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}"/${PN}-${H}

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"

BDEPEND="app-emacs/s"
RDEPEND="
	${BDEPEND}
	app-emacs/julia-mode
"

DOCS=( CHANGELOG.md README.md )
PATCHES=( "${FILESDIR}"/${PN}-force-compile.patch )
SITEFILE="50${PN}-gentoo.el"

src_test() {
	${EMACS} ${EMACSFLAGS} ${BYTECOMPFLAGS}  \
			 -l ert -l ./${PN}-tests.el  \
			 -f ert-run-tests-batch-and-exit || die "tests failed"
}

src_install() {
	rm ./${PN}-tests.el || die

	elisp_src_install
}

pkg_postinst() {
	elisp_pkg_postinst

	optfeature "running Julia inside VTerm" app-emacs/vterm
}