blob: 4c584b1af2c8b234696878145d54b5a9139bb4a7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools elisp-common toolchain-funcs
MY_SNAP="${PV/*_p}"
MY_P="mgp-snap-${MY_SNAP}"
DESCRIPTION="X11 based presentation tool"
HOMEPAGE="http://member.wide.ad.jp/wg/mgp/"
SRC_URI="ftp://sh.wide.ad.jp/WIDE/free-ware/mgp-snap/${MY_P}.tar.gz"
S="${WORKDIR}/kit"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="cjk contrib doc emacs examples fontconfig gif imlib m17n-lib mng nls png truetype"
REQUIRED_USE="imlib? ( !gif !png )"
COMMON_DEPEND="
x11-libs/libICE
x11-libs/libSM
x11-libs/libXmu
x11-libs/libXrender
emacs? ( >=app-editors/emacs-23.1:* )
imlib? ( media-libs/imlib2[X] )
!imlib? (
gif? ( media-libs/giflib:= )
png? ( >=media-libs/libpng-1.4:0= )
)
m17n-lib? (
dev-libs/m17n-lib[X]
fontconfig? ( media-libs/fontconfig )
)
mng? ( media-libs/libmng:= )
truetype? (
x11-libs/libXft
media-libs/fontconfig
)"
RDEPEND="
${COMMON_DEPEND}
contrib? ( dev-lang/perl )
nls? ( sys-devel/gettext )
truetype? ( cjk? ( media-fonts/sazanami ) )"
DEPEND="
${COMMON_DEPEND}
x11-libs/libxkbfile"
BDEPEND="
app-text/rman
virtual/pkgconfig
x11-base/xorg-proto
>=x11-misc/imake-1.0.8-r1
"
SITEFILE="50${PN}-gentoo.el"
PATCHES=(
"${FILESDIR}"/${PN}-1.11b-gentoo.diff
"${FILESDIR}"/${PN}-1.13a_p20121015-fontconfig.patch
"${FILESDIR}"/${PN}-1.13a_p20121015-parse-empty.patch
"${FILESDIR}"/${PN}-1.13a_p20121015-draw-charset.patch
"${FILESDIR}"/${PN}-1.13a_p20121015-draw-stringtoolong.patch
"${FILESDIR}"/${PN}-1.13a_p20121015-implicit-declaration.patch
"${FILESDIR}"/${PN}-1.13a_p20121015-fno-common.patch
)
src_prepare() {
default
sed -i -e '/mgp_version =/s, (.*), ('${MY_SNAP}'),' mgp.c || die
if ! use imlib; then
eapply "${FILESDIR}"/${PN}-1.13a-libpng15.patch
# fix compability with libpng14
sed -i \
-e 's:png_set_gray_1_2_4_to_8:png_set_expand_gray_1_2_4_to_8:' \
configure.in image/png.c || die
if use gif; then
# bug #85720
sed -i -e "s/ungif/gif/g" configure.in || die
# bug #486248
eapply "${FILESDIR}"/${PN}-1.13a_p20121015-any-giflib.patch
# fix use of uninitialized memory in error message
eapply "${FILESDIR}"/${PN}-1.13a_p20121015-gif-dimension.patch
fi
fi
mv configure.{in,ac} || die
eautoreconf
}
src_configure() {
local myeconfargs=(
$(use_enable gif)
$(use_enable imlib)
$(use_enable nls locale)
$(use_enable truetype xft2)
$(use_with m17n-lib)
--disable-freetype
--disable-vflib
--x-libraries="${ESYSROOT}/usr/$(get_libdir)"
--x-includes="${ESYSROOT}/usr/include"
)
tc-export PKG_CONFIG
econf "${myeconfargs[@]}"
export IMAKECPP="${IMAKECPP:-$(tc-getCPP)}"
CC="$(tc-getBUILD_CC)" LD="$(tc-getLD)" xmkmf || die
}
src_compile() {
# no parallel build possible anywhere
emake -j1 CC="$(tc-getBUILD_CC)" LD="$(tc-getLD)" Makefiles
local myemakeargs=(
AR="$(tc-getAR) cq"
CC="$(tc-getCC)"
RANLIB="$(tc-getRANLIB)"
CDEBUGFLAGS="${CFLAGS}"
LOCAL_LDFLAGS="${LDFLAGS}"
BINDIR="${EPREFIX}/usr/bin"
LIBDIR="${EPREFIX}/etc/X11"
)
emake -j1 "${myemakeargs[@]}"
if use emacs; then
pushd contrib >/dev/null || die
elisp-compile *.el
popd >/dev/null || die
fi
}
src_install() {
local myemakeargs=(
DESTDIR="${D}"
BINDIR="${EPREFIX}/usr/bin"
DOCHTMLDIR="${EPREFIX}/usr/share/doc/${PF}"
LIBDIR="${EPREFIX}/etc/X11"
MANPATH="${EPREFIX}/usr/share/man"
MANSUFFIX=1
)
emake -j1 "${myemakeargs[@]}" install install.man
use contrib && dobin contrib/mgp2{html,latex}.pl
if use emacs; then
pushd contrib >/dev/null || die
elisp-install ${PN} *.el *.elc
elisp-site-file-install "${FILESDIR}/${SITEFILE}"
popd >/dev/null || die
fi
dodoc FAQ README* RELNOTES SYNTAX TODO* USAGE*
if use examples; then
# default and mgp[1-3].jpg are already installed
rm sample/{default.mgp,mgp{1,2,3}.jpg} || die
docinto examples
dodoc sample/[^IM]*
fi
}
pkg_postinst() {
elog
elog "If you enabled xft2 support (default) you may specify xfont directive by"
elog "font name and font registry."
elog "e.g.)"
elog '%deffont "standard" xfont "sazanami mincho" "jisx0208.1983"'
elog
use emacs && elisp-site-regen
}
pkg_postrm() {
use emacs && elisp-site-regen
}
|
GitWeb