blob: 5dea03c85f581232661e3bf9dd08b74ca1140a6d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Copyright 2018-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..12} )
inherit edo ninja-utils python-any-r1 toolchain-funcs
DESCRIPTION="GN is a meta-build system that generates build files for Ninja"
HOMEPAGE="https://gn.googlesource.com/"
if [[ ${PV} == 9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://gn.googlesource.com/gn"
else
# The version number is derived from `git describe HEAD --abbrev=12`
SRC_URI="https://deps.gentoo.zip/dev-build/gn/${P}.tar.xz"
KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
fi
LICENSE="BSD"
SLOT="0"
BDEPEND="
${PYTHON_DEPS}
app-alternatives/ninja
"
PATCHES=(
"${FILESDIR}"/gn-gen-r5.patch
)
pkg_setup() {
:
}
src_configure() {
python_setup
tc-export AR CC CXX
if use elibc_musl ; then # bug 906362
export CC="${CC} -D_LARGEFILE64_SOURCE"
export CXX="${CXX} -D_LARGEFILE64_SOURCE"
fi
unset CFLAGS
set -- ${EPYTHON} build/gen.py --no-last-commit-position --no-strip --no-static-libstdc++ --allow-warnings
edo "$@"
cat >out/last_commit_position.h <<-EOF || die
#ifndef OUT_LAST_COMMIT_POSITION_H_
#define OUT_LAST_COMMIT_POSITION_H_
#define LAST_COMMIT_POSITION_NUM ${PV##0.}
#define LAST_COMMIT_POSITION "${PV}"
#endif // OUT_LAST_COMMIT_POSITION_H_
EOF
}
src_compile() {
eninja -C out gn
}
src_test() {
eninja -C out gn_unittests
out/gn_unittests || die
}
src_install() {
dobin out/gn
einstalldocs
insinto /usr/share/vim/vimfiles
doins -r misc/vim/{autoload,ftdetect,ftplugin,syntax}
}
|
GitWeb
