blob: 208e40ffb41ee9a23796b56716f4a29a60c6f078 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
JAVA_PKG_IUSE="doc source test"
MAVEN_ID="org.bouncycastle:bcpkix-jdk18on:1.71"
JAVA_TESTING_FRAMEWORKS="junit-4"
inherit java-pkg-2 java-pkg-simple check-reqs
DESCRIPTION="Java APIs for CMS, PKCS, EAC, TSP, CMP, CRMF, OCSP, and certificate generation"
HOMEPAGE="https://www.bouncycastle.org/java.html"
SRC_URI="https://github.com/bcgit/bc-java/archive/r${PV/./rv}.tar.gz -> bc-java-r${PV/./rv}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
# 1) testSANMismatchIP(org.bouncycastle.est.test.TestHostNameAuthorizer)
# org.bouncycastle.est.ESTException: localhost.me: Temporary failure in name resolution HTTP Status Code: 0
PROPERTIES="test_network"
RESTRICT="test"
CDEPEND="
~dev-java/bcprov-${PV}:0
~dev-java/bcutil-${PV}:0
"
DEPEND="${CDEPEND}
>=virtual/jdk-11:*"
RDEPEND="${CDEPEND}
>=virtual/jre-1.8:*"
DOCS=( ../{README,SECURITY}.md )
HTML_DOCS=( ../{CONTRIBUTORS,index}.html )
S="${WORKDIR}/bc-java-r${PV/./rv}/pkix"
JAVA_GENTOO_CLASSPATH="bcprov,bcutil"
JAVA_SRC_DIR=(
"src/main/java"
"src/main/jdk1.9" # https://bugs.gentoo.org/797634
)
JAVA_TEST_GENTOO_CLASSPATH="junit-4"
JAVA_TEST_SRC_DIR="src/test/java"
JAVA_TEST_RESOURCE_DIRS="src/test/resources"
JAVA_TEST_EXTRA_ARGS="-Dbc.test.data.home=${S}/../core/src/test/data"
# There was 1 failure:
# 1) testSimpleTests(org.bouncycastle.cert.test.AllTests)
# junit.framework.AssertionFailedError: CertTest:
# CertTest: 9 failed - exception java.security.InvalidKeyException: cannot identify EdDSA public key
# at junit.framework.Assert.fail(Assert.java:57)
# at junit.framework.TestCase.fail(TestCase.java:223)
# at org.bouncycastle.cert.test.AllTests.testSimpleTests(AllTests.java:30)
#
# FAILURES!!!
# Tests run: 474, Failures: 1
JAVA_TEST_RUN_ONLY=(
"org.bouncycastle.cert.cmp.test.AllTests"
"org.bouncycastle.cert.crmf.test.AllTests"
"org.bouncycastle.cert.ocsp.test.AllTests"
"org.bouncycastle.cert.path.test.AllTests"
# "org.bouncycastle.cert.test.AllTests"
"org.bouncycastle.cms.test.AllTests"
"org.bouncycastle.dvcs.test.AllTests"
"org.bouncycastle.eac.test.AllTests"
"org.bouncycastle.est.test.AllTests"
"org.bouncycastle.mime.test.AllTests"
"org.bouncycastle.mozilla.test.AllTests"
"org.bouncycastle.openssl.test.AllTests"
"org.bouncycastle.operator.test.AllTests"
"org.bouncycastle.pkcs.test.AllTests"
"org.bouncycastle.tsp.test.AllTests"
)
# https://bugs.gentoo.org/823347
check_env() {
if use test; then
# this is needed only for tests
CHECKREQS_MEMORY="2048M"
check-reqs_pkg_pretend
fi
}
# https://bugs.gentoo.org/823347
pkg_pretend() {
check_env
}
# https://bugs.gentoo.org/823347
pkg_setup() {
check_env
java-pkg-2_pkg_setup
}
src_prepare() {
default
java-pkg_clean ..
}
# https://bugs.gentoo.org/823347
src_test() {
JAVA_TEST_EXTRA_ARGS+=" -Xmx${CHECKREQS_MEMORY}"
java-pkg-simple_src_test
}
src_install() {
default
einstalldocs
docinto html
dodoc -r ../docs
java-pkg-simple_src_install
}
|
GitWeb