blob: 6abd1ee29121b14cd4985ca19bcfd5226d844cf5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit eapi7-ver java-vm-2
abi_uri() {
local os=linux
case ${2} in
*-macos) os=mac ;;
*-solaris) os=solaris ;;
esac
echo "${2-$1}? (
https://github.com/adoptium/temurin${SLOT}-binaries/releases/download/jdk${MY_PV}/OpenJDK8U-jdk_${1}_${os}_hotspot_${3-${MY_PV/-/}}.tar.gz
)"
}
# they have different tarball names for different arches...
# https://github.com/AdoptOpenJDK/openjdk8-binaries/releases/download/jdk8u282-b08/OpenJDK8U-jdk_x64_linux_hotspot_8u282b08.tar.gz
# https://github.com/AdoptOpenJDK/openjdk8-binaries/releases/download/jdk8u282-b08/OpenJDK8U-jdk_aarch64_linux_hotspot_jdk8u282-b08.tar.gz
MY_PV=$(ver_rs 1 'u' 2 '-' ${PV//p/b})
SLOT="$(ver_cut 1)"
DESCRIPTION="Prebuilt Java JDK binaries provided by Eclipse Temurin"
HOMEPAGE="https://adoptium.net"
SRC_URI="
$(abi_uri aarch64 arm64)
$(abi_uri arm)
$(abi_uri ppc64le ppc64)
$(abi_uri x64 amd64)
$(abi_uri x64 x64-macos)
"
LICENSE="GPL-2-with-classpath-exception"
KEYWORDS="amd64 ~arm arm64 ppc64 ~x64-macos"
IUSE="alsa cups examples headless-awt selinux source"
RDEPEND="
>=sys-apps/baselayout-java-0.1.0-r1
kernel_linux? (
media-libs/fontconfig:1.0
media-libs/freetype:2
>=sys-libs/glibc-2.2.5:*
sys-libs/zlib
alsa? ( media-libs/alsa-lib )
arm? ( dev-libs/libffi-compat:6 )
cups? ( net-print/cups )
selinux? ( sec-policy/selinux-java )
!headless-awt? (
x11-libs/libX11
x11-libs/libXext
x11-libs/libXi
x11-libs/libXrender
x11-libs/libXtst
)
)
"
RESTRICT="preserve-libs strip"
QA_PREBUILT="*"
S="${WORKDIR}/jdk${MY_PV}"
src_unpack() {
default
# 753575
if use arm; then
mv -v "${S}"* "${S}" || die
elif [[ ${A} == *_mac_* ]] ; then
mv -v "${S}/Contents/Home/"* "${S}" || die
rm -Rf "${S}/Contents" # drop macOS executable
fi
}
src_install() {
local dest="/opt/${P}"
local ddest="${ED%/}/${dest#/}"
rm ASSEMBLY_EXCEPTION LICENSE THIRD_PARTY_README || die
# on macOS if they would exist they would be called .dylib, but most
# importantly, there are no different providers, so everything
# that's shipped works.
if [[ ${A} != *_mac_* ]] ; then
# this does not exist on arm64 hence -f
rm -fv jre/lib/*/libfreetype.so* || die
if ! use alsa ; then
rm -v jre/lib/*/libjsoundalsa.so* || die
fi
if ! use examples ; then
rm -vr sample || die
fi
if use headless-awt ; then
rm -fvr {,jre/}lib/*/lib*{[jx]awt,splashscreen}* \
{,jre/}bin/policytool bin/appletviewer || die
fi
fi
if ! use source ; then
rm -v src.zip || die
fi
rm -v jre/lib/security/cacerts || die
dosym ../../../../../etc/ssl/certs/java/cacerts \
"${dest}"/jre/lib/security/cacerts
dodir "${dest}"
cp -pPR * "${ddest}" || die
# provide stable symlink
dosym "${P}" "/opt/${PN}-${SLOT}"
java-vm_install-env "${FILESDIR}"/${PN}-${SLOT}.env.sh
java-vm_set-pax-markings "${ddest}"
java-vm_revdep-mask
java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
}
|
GitWeb