blob: e7ec8bf4f0d7d07edfade31f0100cbc9e21a9d9a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
|
# Copyright 2014-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI="7"
PYTHON_COMPAT=(python{3_6,3_7})
DISTUTILS_OPTIONAL="1"
inherit autotools distutils-r1
if [[ "${PV}" == "9999" ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/s-yata/marisa-trie"
fi
DESCRIPTION="Matching Algorithm with Recursively Implemented StorAge"
HOMEPAGE="https://github.com/s-yata/marisa-trie https://code.google.com/archive/p/marisa-trie/"
if [[ "${PV}" == "9999" ]]; then
SRC_URI=""
else
SRC_URI="https://github.com/s-yata/marisa-trie/archive/v${PV}.tar.gz -> ${P}.tar.gz"
fi
LICENSE="|| ( BSD-2 LGPL-2.1+ )"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_ssse3 cpu_flags_x86_sse4_1 cpu_flags_x86_sse4_2 cpu_flags_x86_sse4a cpu_flags_x86_popcnt python static-libs"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
cpu_flags_x86_sse3? ( cpu_flags_x86_sse2 )
cpu_flags_x86_ssse3? ( cpu_flags_x86_sse3 )
cpu_flags_x86_sse4_1? ( cpu_flags_x86_ssse3 )
cpu_flags_x86_sse4_2? ( cpu_flags_x86_popcnt cpu_flags_x86_sse4_1 )
cpu_flags_x86_sse4a? ( cpu_flags_x86_popcnt cpu_flags_x86_sse3 )
cpu_flags_x86_popcnt? ( cpu_flags_x86_sse3 )"
BDEPEND="python? (
${PYTHON_DEPS}
dev-lang/swig
)"
DEPEND="python? ( ${PYTHON_DEPS} )"
RDEPEND="${DEPEND}"
if [[ "${PV}" != "9999" ]]; then
S="${WORKDIR}/marisa-trie-${PV}"
fi
src_prepare() {
default
eautoreconf
sed -e "s:^\([[:space:]]*\)libraries=:\1include_dirs=[\"../../include\"],\n\1library_dirs=[\"../../lib/marisa/.libs\"],\n&:" -i bindings/python/setup.py || die
if use python; then
pushd bindings/python > /dev/null || die
distutils-r1_src_prepare
popd > /dev/null || die
fi
}
src_configure() {
local options=(
$(use_enable cpu_flags_x86_sse2 sse2)
$(use_enable cpu_flags_x86_sse3 sse3)
$(use_enable cpu_flags_x86_ssse3 ssse3)
$(use_enable cpu_flags_x86_sse4_1 sse4.1)
$(use_enable cpu_flags_x86_sse4_2 sse4.2)
$(use_enable cpu_flags_x86_sse4a sse4a)
$(use_enable cpu_flags_x86_popcnt popcnt)
$(use_enable static-libs static)
)
econf "${options[@]}"
if use python; then
pushd bindings/python > /dev/null || die
distutils-r1_src_configure
popd > /dev/null || die
fi
}
src_compile() {
default
if use python; then
emake -C bindings swig-python
pushd bindings/python > /dev/null || die
distutils-r1_src_compile
popd > /dev/null || die
fi
}
src_install() {
default
find "${D}" -name "*.la" -type f -delete || die
(
docinto html
dodoc docs/*
)
if use python; then
pushd bindings/python > /dev/null || die
distutils-r1_src_install
popd > /dev/null || die
fi
}
|
GitWeb