blob: 6b9032f095b112a6f885f704a0f2e9fde8201695 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
DIST_AUTHOR=RAZ
DIST_VERSION=0.25
DIST_EXAMPLES=("script/*")
inherit perl-module
DESCRIPTION="Perl client for memcached, in C language"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="test"
RESTRICT="!test? ( test )"
PATCHES=(
"${FILESDIR}/0.230.0-parallel-make.patch"
"${FILESDIR}/${P}-no-flto.patch"
)
RDEPEND="virtual/perl-Storable"
DEPEND="${RDEPEND}
virtual/perl-ExtUtils-MakeMaker
test? (
net-misc/memcached
virtual/perl-Test-Simple
)
"
src_test() {
perl_rm_files t/pod-coverage.t t/pod.t
local memcached_opts=( -d -P "${T}/memcached.pid" -p 11211 -l 127.0.0.1 )
[[ ${EUID} == 0 ]] && memcached_opts+=( -u portage )
memcached "${memcached_opts[@]}" || die "Can't start memcached test server"
local exit_status
perl-module_src_test
exit_status=$?
kill "$(<"${T}/memcached.pid")"
return ${exit_status}
}
|
GitWeb
