blob: 5a7c22168e0196fe26e3160ec9de2b56fa0a3880 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{7..9} )
inherit distutils-r1
DESCRIPTION="Diff and merge of Jupyter Notebooks"
HOMEPAGE="https://jupyter.org"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64"
IUSE="webtools"
RDEPEND="
dev-python/colorama[${PYTHON_USEDEP}]
dev-python/GitPython[${PYTHON_USEDEP}]
dev-python/jinja[${PYTHON_USEDEP}]
dev-python/jupyter_server[${PYTHON_USEDEP}]
dev-python/jupyter_server_mathjax[${PYTHON_USEDEP}]
dev-python/nbformat[${PYTHON_USEDEP}]
dev-python/pygments[${PYTHON_USEDEP}]
dev-python/requests[${PYTHON_USEDEP}]
www-servers/tornado[${PYTHON_USEDEP}]
webtools? ( net-libs/nodejs[npm] )"
BDEPEND="
test? (
dev-python/jsonschema[${PYTHON_USEDEP}]
dev-python/mock[${PYTHON_USEDEP}]
dev-python/notebook[${PYTHON_USEDEP}]
dev-python/pytest-timeout[${PYTHON_USEDEP}]
dev-python/tabulate[${PYTHON_USEDEP}]
)"
distutils_enable_sphinx docs/source \
dev-python/recommonmark \
dev-python/sphinx_rtd_theme
distutils_enable_tests --install pytest
python_prepare_all() {
# yield tests were removed in pytest 4.0
sed -i -e 's/test_offline_mathjax/_&/' \
-e 's/test_api_merge/_&/' \
-e 's/test_fetch_merge/_&/' \
-e 's/test_api_diff/_&/' \
-e 's/test_fetch_diff/_&/' \
nbdime/tests/test_web.py || die
sed -i -e 's/test_git_difftool/_&/' \
nbdime/tests/test_server_extension.py || die
# reason: [NOTRUN] flaws in deep diffing of lists, not identifying almost equal sublists
sed -i -e 's/test_deep_merge_lists_delete_no_conflict__currently_expected_failures/_&/' \
nbdime/tests/test_merge.py || die
sed -i -e 's/test_diff_to_json_patch/_&/' \
nbdime/tests/test_diff_json_conversion.py || die
sed -i -e 's/test_build_diffs_unsorted/_&/' \
nbdime/tests/test_decision_tools.py || die
sed -i -e 's/test_merge_multiline_cell_source_conflict/_&/' \
-e 's/test_merge_interleave_cell_add_remove/_&/' \
-e 's/test_merge_conflicts_get_diff_indices_shifted/_&/' \
-e 's/test_merge_inserts_within_deleted_range/_&/' \
nbdime/tests/test_merge_notebooks.py || die
distutils-r1_python_prepare_all
}
python_configure_all() {
use webtools || mydistutilsargs=( --skip-npm )
}
src_test() {
# user.email and user.name are not configured in the sandbox
git config --global user.email "larry@gentoo.org" || die
git config --global user.name "Larry the Cow" || die
python_foreach_impl python_test
}
|
GitWeb