blob: 1e825003ff3c084170bdb36fa6854a2b69ffa72c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
EAPI=7
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{8..10} pypy3 )
inherit distutils-r1
DESCRIPTION="Python Lex-Yacc library"
HOMEPAGE="
http://www.dabeaz.com/ply/
https://github.com/dabeaz/ply/
https://pypi.org/project/ply/
"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="BSD"
SLOT="0/${PV}"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="examples"
DOCS=( ANNOUNCE CHANGES TODO )
PATCHES=(
"${FILESDIR}/3.6-picklefile-IOError.patch"
)
python_test() {
# Checks for pyc/pyo files
local -x PYTHONDONTWRITEBYTECODE=
cd test || die
local t
for t in testlex.py testyacc.py; do
"${EPYTHON}" "${t}" -v || die "${t} fails with ${EPYTHON}"
done
}
python_install_all() {
local HTML_DOCS=( doc/. )
use examples && dodoc -r example
distutils-r1_python_install_all
}
|
GitWeb
