dev-python/sphinxcontrib-asyncio/sphinxcontrib-asyncio-0.3.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{8..11} )

inherit distutils-r1

DESCRIPTION="sphinx extension to support coroutines in markup"
HOMEPAGE="
	https://github.com/aio-libs/sphinxcontrib-asyncio/
	https://pypi.org/project/sphinxcontrib-asyncio/
"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux"

RDEPEND="
	dev-python/sphinx[${PYTHON_USEDEP}]
"

distutils_enable_sphinx docs

src_prepare() {
	# fix for sphinx >= 4.0
	sed -e 's/PyModulelevel/PyFunction/g' \
		-e 's/PyClassmember/PyClassMethod/g' \
		-i sphinxcontrib/asyncio.py || die
	default
}

python_compile() {
	distutils-r1_python_compile
	rm "${BUILD_DIR}/install$(python_get_sitedir)"/sphinxcontrib/__init__.py || die
}