blob: f8c38b620318f85d1fd4357e7f97773223804487 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=5
PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
inherit distutils-r1
DESCRIPTION="HTTP library with thread-safe connection pooling, file post, and more"
HOMEPAGE="https://github.com/shazow/urllib3"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 arm ~hppa ~ppc ~ppc64 ~x86"
IUSE="doc test"
RDEPEND="dev-python/six[${PYTHON_USEDEP}]
$(python_gen_cond_dep \
'dev-python/backports-ssl-match-hostname[${PYTHON_USEDEP}]' python2_7 pypy)"
DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
test? (
${RDEPEND}
~www-servers/tornado-3.1.1[${PYTHON_USEDEP}]
$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7 pypy)
dev-python/nose[${PYTHON_USEDEP}] )
doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
"
python_prepare_all() {
# Replace bundled copy of dev-python/six
cat > urllib3/packages/six.py <<-EOF
from __future__ import absolute_import
from six import *
EOF
sed -i 's:cover-min-percentage = 100::' setup.cfg || die
# Fix tests
sed -i 's/urllib3.packages.six/six/' test/test_retry.py || die
# Reset source of objects.inv
if use doc; then
local PYTHON_DOC_ATOM=$(best_version --host-root dev-python/python-docs:2.7)
local PYTHON_DOC_VERSION="${PYTHON_DOC_ATOM#dev-python/python-docs-}"
local PYTHON_DOC="/usr/share/doc/python-docs-${PYTHON_DOC_VERSION}/html"
local PYTHON_DOC_INVENTORY="${PYTHON_DOC}/objects.inv"
sed -i "s|'python': ('http://docs.python.org/2.7', None|'${PYTHON_DOC}': ('${PYTHON_DOC_INVENTORY}'|" docs/conf.py || die
fi
distutils-r1_python_prepare_all
}
python_compile_all() {
use doc && emake -C docs html
}
python_test() {
# __init__.py uses a local import requiring use of PYTHONPATH=blank to offset
# Failures currently occur under py2.7. After joint testing
# it's planned for this to have further investigation.
# https://github.com/shazow/urllib3/issues/621
# These tests fail with network-sandbox enable due to an arbitrary "tarpit"
# address (10.255.255.1) being non-routable.
local exclude=(
-e test_enhanced_timeout
-e test_https_timeout
-e test_https_proxy_pool_timeout
-e test_https_proxy_timeout
)
PYTHONPATH= nosetests "${exclude[@]}" test || die "Tests fail with ${EPYTHON}"
}
python_install_all() {
use doc && local HTML_DOCS=( docs/_build/html/. )
distutils-r1_python_install_all
}
|
GitWeb