blob: 154eb8d2deda42b5e317c1f207d619afa487a46b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{7..10} pypy3 )
inherit distutils-r1
DESCRIPTION="Collection of various utilities for WSGI applications"
HOMEPAGE="
https://werkzeug.palletsprojects.com/
https://pypi.org/project/Werkzeug/
https://github.com/pallets/werkzeug/"
SRC_URI="
https://github.com/pallets/werkzeug/archive/${PV}.tar.gz
-> ${P}.gh.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
BDEPEND="
test? (
dev-python/cryptography[${PYTHON_USEDEP}]
!hppa? ( !ia64? (
$(python_gen_cond_dep '
dev-python/greenlet[${PYTHON_USEDEP}]
' 'python*')
) )
dev-python/pytest-timeout[${PYTHON_USEDEP}]
dev-python/pytest-xprocess[${PYTHON_USEDEP}]
dev-python/watchdog[${PYTHON_USEDEP}]
)"
distutils_enable_tests pytest
PATCHES=(
"${FILESDIR}"/${P}-py310.patch
)
src_prepare() {
distutils-r1_src_prepare
# prevent esetup.py install from zipping the egg
sed -i -e '/\[options\]/azip_safe = False' setup.cfg || die
}
python_test() {
"${EPYTHON}" -m venv --system-site-packages --without-pip \
"${BUILD_DIR}"/venv || die
local -x PATH=${BUILD_DIR}/venv/bin:${PATH}
unset PYTHONPATH
esetup.py install
# the default portage tempdir is too long for AF_UNIX sockets
local -x TMPDIR=/tmp
epytest -p no:httpbin tests
}
|
GitWeb
