blob: dbbcfc8b9eaef24bbc57dc6d868495e3b4306a28 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
USE_RUBY="ruby31 ruby32 ruby33"
RUBY_FAKEGEM_TASK_TEST="CUCUMBER_PUBLISH_QUIET=true test features"
RUBY_FAKEGEM_EXTRADOC="CHANGELOG.adoc README.adoc"
RUBY_FAKEGEM_EXTRAINSTALL="data"
RUBY_FAKEGEM_GEMSPEC="asciidoctor.gemspec"
inherit ruby-fakegem
DESCRIPTION="Processor for converting AsciiDoc into HTML 5, DocBook 4.5 and other formats"
HOMEPAGE="https://github.com/asciidoctor/asciidoctor"
SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~x86"
IUSE="test"
ruby_add_bdepend "test? (
dev-util/cucumber
dev-ruby/rspec-expectations:*
dev-ruby/asciimath
dev-ruby/coderay
dev-ruby/concurrent-ruby
dev-ruby/erubi
dev-ruby/haml:6
dev-ruby/nokogiri
dev-ruby/rouge
dev-ruby/slim
dev-ruby/tilt )"
all_ruby_prepare() {
rm Gemfile || die
sed -i -e "s:_relative ': './:" ${RUBY_FAKEGEM_GEMSPEC} || die
# Avoid broken blocks_test.rb (already appears to be fixed upstream)
rm -f test/blocks_test.rb || die
# Avoid test depending on haml 6 binary which we currently don't install.
sed -e '/should \(load\|locate\) custom templates/askip "wrong haml binary"' \
-i test/invoker_test.rb || die
# Add missing require for URI
sed -e "/nokogiri/arequire 'uri'" \
-i test/test_helper.rb || die
}
all_ruby_install() {
all_fakegem_install
doman man/asciidoctor.1
}
|
GitWeb
