blob: 01bf024b29a0613b648c70f9e8dd9676ecd4640b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{8..10} )
# vala-0.36 fails to build, https://bugs.gentoo.org/692538
VALA_MIN_API_VERSION="0.40"
inherit gnome.org gnome2-utils meson python-r1 vala xdg-utils
DESCRIPTION="git repository viewer for GNOME"
HOMEPAGE="https://wiki.gnome.org/Apps/Gitg"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="glade +python"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
# test if unbundling of libgd is possible
# Currently it seems not to be (unstable API/ABI)
RDEPEND="
app-crypt/libsecret[vala]
>=app-text/gspell-1[vala]
>=dev-libs/glib-2.38:2[dbus]
>=dev-libs/gobject-introspection-0.10.1:=
dev-libs/json-glib
dev-libs/libdazzle[vala]
dev-libs/libgee:0.8[introspection]
dev-libs/libgit2:=[threads]
>=dev-libs/libgit2-glib-1.0.0[ssh]
>=dev-libs/libpeas-1.5.0[gtk]
>=dev-libs/libxml2-2.9.0:2
>=gnome-base/gsettings-desktop-schemas-0.1.1
>=x11-libs/gtk+-3.20.0:3
>=x11-libs/gtksourceview-4.0.3:4
x11-themes/adwaita-icon-theme
glade? ( >=dev-util/glade-3.2:3.10 )
python? (
${PYTHON_DEPS}
dev-python/pygobject:3[${PYTHON_USEDEP}]
)
"
DEPEND="${RDEPEND}
$(vala_depend)
>=dev-libs/libgit2-glib-1.0.0[vala]
>=sys-devel/gettext-0.19.7
virtual/pkgconfig
"
PATCHES=(
"${FILESDIR}/${PV}"-fix-build-with-meson-0.61.1.patch
)
src_prepare() {
default
vala_src_prepare
xdg_environment_reset
# it doesn't do anything in DESTDIR mode, except for failing
# when python3 symlink is not present
echo "#!/bin/sh" > meson_post_install.py || die
}
src_configure() {
local emesonargs=(
$(meson_use glade glade_catalog)
# we install the module manually anyway
-Dpython=false
)
meson_src_configure
}
src_install() {
meson_src_install
if use python ; then
python_moduleinto gi.overrides
python_foreach_impl python_domodule libgitg-ext/GitgExt.py
fi
}
pkg_postinst() {
gnome2_schemas_update
xdg_desktop_database_update
xdg_icon_cache_update
}
pkg_postrm() {
gnome2_schemas_update
xdg_desktop_database_update
xdg_icon_cache_update
}
|
GitWeb