blob: b308fb3d0b5057374ad8f87b281a6044c2c69986 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake desktop xdg flag-o-matic
DESCRIPTION="A modder-friendly OpenGL source port based on the DOOM engine"
HOMEPAGE="https://zdoom.org"
SRC_URI="https://github.com/coelckers/${PN}/archive/g${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/${PN}-g${PV}"
LICENSE="Apache-2.0 BSD BZIP2 GPL-3 LGPL-2.1+ LGPL-3 MIT
non-free? ( Activision ChexQuest3 DOOM-COLLECTORS-EDITION freedist WidePix )"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~ppc64"
IUSE="debug gles2 gtk +non-free openmp +swr telemetry vulkan"
DEPEND="
app-arch/bzip2
media-libs/libjpeg-turbo:0=
media-libs/libsdl2[gles2?,opengl,vulkan?]
media-libs/libvpx:=
media-libs/libwebp
media-libs/openal
media-libs/zmusic
sys-libs/zlib
gtk? ( x11-libs/gtk+:3 )"
RDEPEND="${DEPEND}"
PATCHES=(
"${FILESDIR}"/${PN}-4.7.1-Introduce-the-BUILD_NONFREE-option.patch
)
src_prepare() {
rm -rf docs/licenses || die
rm -rf libraries/{bzip2,jpeg,zlib} || die
if ! use non-free ; then
rm -rf wadsrc_bm wadsrc_extra wadsrc_widepix || die
fi
{
echo "// 0"
echo "// The above line prevents UpdateRevision.cmake from replacing this file."
echo "// This file was generated by the Gentoo ebuild."
echo
echo "#define GIT_DESCRIPTION \"g${PV}\""
echo "#define GIT_HASH \"0\""
echo "#define GIT_TIME \"\""
} > "${S}/src/gitinfo.h" || die
cmake_src_prepare
}
src_configure() {
# https://bugs.gentoo.org/858749
filter-lto
append-flags -fno-strict-aliasing
local mycmakeargs=(
-DBUILD_SHARED_LIBS=OFF
-DINSTALL_DOCS_PATH="${EPREFIX}/usr/share/doc/${PF}"
-DINSTALL_PK3_PATH="${EPREFIX}/usr/share/doom"
-DINSTALL_SOUNDFONT_PATH="${EPREFIX}/usr/share/doom"
-DDYN_OPENAL=OFF
-DNO_GTK="$(usex !gtk)"
-DNO_OPENAL=OFF
-DHAVE_VULKAN="$(usex vulkan)"
-DHAVE_GLES2="$(usex gles2)"
-DNO_OPENMP="$(usex !openmp)"
-DZDOOM_ENABLE_SWR="$(usex swr)"
-DBUILD_NONFREE="$(usex non-free)"
)
use debug || append-cppflags -DNDEBUG
use telemetry || append-cppflags -DNO_SEND_STATS
cmake_src_configure
}
src_install() {
newicon src/posix/zdoom.xpm "${PN}.xpm"
make_desktop_entry "${PN}" "GZDoom" "${PN}" "Game;ActionGame"
cmake_src_install
}
pkg_postinst() {
xdg_pkg_postinst
if ! use non-free ; then
ewarn
ewarn "GZDoom installed without non-free components."
ewarn "Note: The non-free game_support.pk3 file is needed to play"
ewarn " games natively supported by GZDoom."
ewarn "A list of games natively supported by GZDoom is available"
ewarn "on the ZDoom wiki: https://zdoom.org/wiki/IWAD"
ewarn
fi
}
|
GitWeb