blob: 81cfe01a560425b77ea98778927958b3f9be7f1a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit desktop toolchain-funcs
DESCRIPTION="Puzzle game where it's your job to clear the screen of gems"
HOMEPAGE="http://www.newbreedsoftware.com/gemdropx/"
SRC_URI="ftp://ftp.tuxpaint.org/unix/x/gemdropx/src/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
RDEPEND="
media-libs/libsdl[joystick,sound,video]
media-libs/sdl-mixer[mod]"
DEPEND="${RDEPEND}"
src_prepare() {
default
sed -i \
-e 's/$(CFLAGS) -o/$(LDFLAGS) -o/' \
Makefile || die
rm -r data/images/.xvpics || die
}
src_compile() {
local myemakeargs=(
CC="$(tc-getCC)"
CXX="$(tc-getCC)"
DATA_PREFIX="${EPREFIX}/usr/share/${PN}"
XTRA_FLAGS="${CFLAGS}"
)
emake "${myemakeargs[@]}"
}
src_install() {
dobin ${PN}
insinto /usr/share/${PN}
doins -r data/.
dodoc AUTHORS.txt CHANGES.txt ICON.txt README.txt TODO.txt
newicon data/images/${PN}-icon.xpm ${PN}.xpm
make_desktop_entry ${PN} "Gem Drop X"
}
|
GitWeb
