gnome-extra/gnome-shell-extension-bluetooth-quick-connect/gnome-shell-extension-bluetooth-quick-connect-10.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

DESCRIPTION="Allow to connect bluetooth paired devices from gnome control panel"
HOMEPAGE="https://github.com/bjarosze/gnome-bluetooth-quick-connect"
SRC_URI="https://github.com/bjarosze/gnome-bluetooth-quick-connect/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

# glib for glib-compile-schemas at build time, needed at runtime anyways
COMMON_DEPEND="
	dev-libs/glib:2
"
RDEPEND="${COMMON_DEPEND}
	net-wireless/bluez
	app-eselect/eselect-gnome-shell-extensions
	>=gnome-base/gnome-shell-3.26.2
"
DEPEND="${COMMON_DEPEND}"
BDEPEND=""

S="${WORKDIR}/${P/shell-extension-}"

PATCHES=(
	"${FILESDIR}"/${P}-3.34.patch
)

src_install() {
	einstalldocs
	rm -f README.md LICENSE Makefile || die
	insinto /usr/share/gnome-shell/extensions/bluetooth-quick-connect@bjarosze.gmail.com
	doins -r *
	glib-compile-schemas "${ED}"/usr/share/gnome-shell/extensions/bluetooth-quick-connect@bjarosze.gmail.com/schemas || die
}

pkg_postinst() {
	ebegin "Updating list of installed extensions"
	eselect gnome-shell-extensions update
	eend $?
}