media-fonts/mplus-outline-fonts/mplus-outline-fonts-0_pre063_p1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI="7"

inherit font

MY_P="mplus-${PV/0_pre/TESTFLIGHT-}"
MY_P="${MY_P/_p1/a}"

DESCRIPTION="M+ Japanese outline fonts"
HOMEPAGE="https://mplus-fonts.osdn.jp/about-en.html"
SRC_URI="mirror://sourceforge.jp/mplus-fonts/62344/${MY_P}.tar.xz"

LICENSE="mplus-fonts ipafont? ( IPAfont )"
SLOT="0"
KEYWORDS="amd64 ~hppa ~ia64 ppc x86 ~ppc-macos"
IUSE="ipafont"
RESTRICT="binchecks strip"

BDEPEND="ipafont? (
		media-fonts/ja-ipafonts
		media-gfx/fontforge
	)"
S="${WORKDIR}/${MY_P}"

DOCS=( README_J README_E )

FONT_SUFFIX="ttf"

IPAFONT_DIR="${EPREFIX}/usr/share/fonts/ja-ipafonts"

src_prepare() {
	if use ipafont; then
		cp -p "${IPAFONT_DIR}"/ipag.ttf . || die
	fi
	default
}

src_compile() {
	if use ipafont; then
		fontforge -script m++ipa.pe || die
		rm ipag.ttf || die
	fi
}