media-libs/adplug/adplug-2.3.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit out-of-source

DESCRIPTION="A free, cross-platform, hardware independent AdLib sound player library"
HOMEPAGE="http://adplug.github.io/"

if [[ ${PV} == *9999 ]]; then
	inherit autotools git-r3
	EGIT_REPO_URI="https://github.com/adplug/adplug.git"
else
	SRC_URI="https://github.com/adplug/${PN}/releases/download/${P}/${P}.tar.bz2"
	KEYWORDS="~alpha amd64 arm ~hppa ~ppc ~ppc64 x86"
fi

LICENSE="LGPL-2.1"
SLOT="0/${PV}"
IUSE="debug static-libs"

RDEPEND=">=dev-cpp/libbinio-1.4"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

src_prepare() {
	default
	[[ ${PV} == *9999 ]] && eautoreconf
}

my_src_configure() {
	econf \
		$(use_enable static-libs static) \
		$(use_enable debug)
}

my_src_install_all() {
	einstalldocs
	find "${D}" -name '*.la' -delete || die
}