blob: b540f1e938d7d63fd2197e8b1050ead11f0ff60e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit multilib toolchain-funcs multilib-minimal
MY_P="cmt_${PV}"
S="${WORKDIR}/${MY_P}"
DESCRIPTION="CMT (computer music toolkit) LADSPA library plugins"
HOMEPAGE="https://www.ladspa.org/"
SRC_URI="https://www.ladspa.org/download/${MY_P}.tgz"
KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~loong ppc ppc64 ~riscv sparc x86"
LICENSE="LGPL-2.1"
SLOT="0"
IUSE=""
DEPEND=">=media-libs/ladspa-sdk-1.13-r2[${MULTILIB_USEDEP}]"
RDEPEND=""
PATCHES=(
"${FILESDIR}/${P}-makefile.patch"
"${FILESDIR}/${P}-clang.patch"
)
DOCS="../README"
HTML_DOCS="../doc/*"
src_prepare() {
default
use elibc_Darwin && eapply "${FILESDIR}/${P}-darwin.patch"
multilib_copy_sources
}
multilib_src_compile() {
cd src
tc-export CXX
emake PLUGIN_LIB="cmt.so"
}
multilib_src_install() {
cd src
insopts -m755
insinto /usr/$(get_libdir)/ladspa
doins *.so
}
multilib_src_install_all() {
cd src
insinto /usr/share/ladspa/rdf/
doins "${FILESDIR}/cmt.rdf"
einstalldocs
}
|
GitWeb
