media-plugins/vdr-undelete/vdr-undelete-0.0.7-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=5

inherit vdr-plugin-2

VERSION="1060" # every bump, new version!

DESCRIPTION="VDR Plugin: Recover deleted recordings of VDR"
HOMEPAGE="http://projects.vdr-developer.org/projects/plg-undelete"
SRC_URI="mirror://vdr-developerorg/${VERSION}/${P}.tgz"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="amd64 x86"
IUSE=""

DEPEND=">=media-video/vdr-1.5.7"
RDEPEND="${DEPEND}"

src_prepare() {
	vdr-plugin-2_src_prepare

	if has_version ">=media-video/vdr-2.1.2"; then
		sed -e "s#VideoDirectory#cVideoDirectory::Name\(\)#" \
			-i menuundelete.c

		sed -e "s#RemoveVideoFile#cVideoDirectory::RemoveVideoFile#" \
			-i undelete.c menuundelete.c

		sed -e "s#RenameVideoFile#cVideoDirectory::RenameVideoFile#" \
			-i undelete.c menuundelete.c

		sed -e "s#RemoveEmptyVideoDirectories#cVideoDirectory::RemoveEmptyVideoDirectories#" \
			-i undelete.c
	fi
}