blob: a60fd556fd2bfdf9f022797626fa00e81afa6765 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{8..10} )
inherit gnome.org gnome2-utils meson python-single-r1 xdg
DESCRIPTION="Music management for Gnome"
HOMEPAGE="https://wiki.gnome.org/Apps/Music"
LICENSE="GPL-2+"
SLOT="0"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
KEYWORDS="amd64 arm64 ~ppc64 ~riscv x86"
DEPEND="${PYTHON_DEPS}
>=dev-libs/glib-2.67.1:2
>=net-libs/gnome-online-accounts-3.35.90[introspection]
>=dev-libs/gobject-introspection-1.54:=
>=x11-libs/gtk+-3.24.14:3[introspection]
>=gui-libs/libhandy-1.2.0:1=[introspection]
>=dev-libs/libdazzle-3.28.0[introspection]
>=media-libs/libmediaart-1.9.1:2.0[introspection]
net-libs/libsoup:2.4[introspection]
app-misc/tracker:3=[introspection(+)]
>=x11-libs/pango-1.44:=
$(python_gen_cond_dep '
>=dev-python/pygobject-3.36.1:3[cairo,${PYTHON_USEDEP}]
>=dev-python/pycairo-1.14.0[${PYTHON_USEDEP}]
')
>=media-libs/grilo-0.3.13:0.3[introspection]
>=media-plugins/grilo-plugins-0.3.13:0.3
"
# xdg-user-dirs-update needs to be there to create needed dirs
# https://bugzilla.gnome.org/show_bug.cgi?id=731613
RDEPEND="${DEPEND}
|| (
app-misc/tracker-miners:3[gstreamer]
app-misc/tracker-miners:3[ffmpeg]
)
x11-libs/libnotify[introspection]
media-libs/gstreamer:1.0[introspection]
media-libs/gst-plugins-base:1.0[introspection]
media-plugins/gst-plugins-meta:1.0
media-plugins/grilo-plugins:0.3[tracker]
x11-misc/xdg-user-dirs
"
BDEPEND="
dev-libs/libxml2:2
dev-util/itstool
>=sys-devel/gettext-0.19.8
virtual/pkgconfig
"
PATCHES=(
"${FILESDIR}"/40.1.1-fix-build-with-meson-0.61.1.patch
)
RESTRICT="test" # only does desktop and appdata validation, and latter needs network to validate screenshot from https
pkg_setup() {
python_setup
}
src_install() {
meson_src_install
python_fix_shebang "${D}"/usr/bin/gnome-music
python_optimize
}
pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update
}
pkg_postrm() {
xdg_pkg_postrm
gnome2_schemas_update
}
|
GitWeb