blob: 13bee49ab7af9180a37b1ab10c96caeb151b81dd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10,11,12} pypy3 )
inherit meson python-any-r1
DESCRIPTION="LC3 is an efficient low latency audio codec"
HOMEPAGE="https://github.com/google/liblc3"
SRC_URI="https://github.com/google/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="Apache-2.0"
SLOT="0"
IUSE="test tools"
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
RESTRICT="!test? ( test )"
DEPEND="test? (
$(python_gen_any_dep '
dev-python/numpy[${PYTHON_USEDEP}]
dev-python/scipy[${PYTHON_USEDEP}]
')
)"
python_check_deps() {
python_has_version -d "dev-python/numpy[${PYTHON_USEDEP}]" &&
python_has_version -d "dev-python/scipy[${PYTHON_USEDEP}]"
}
pkg_setup() {
use test && python-any-r1_pkg_setup
}
src_prepare() {
use arm || rm -rf "test/arm" || die
use arm64 || rm -rf "test/neon" || die
default
}
src_configure() {
local emesonargs=(
# We let users choose to enable LTO
-Db_lto=false
$(meson_use tools)
)
meson_src_configure
}
src_test() {
V= emake test CFLAGS:="${CPPFLAGS} ${CFLAGS} -I"$("${EPYTHON}" -c "import numpy;print(numpy.get_include())")""
}
|
GitWeb
