summaryrefslogtreecommitdiff
blob: 6476c056f6db37ce3018790242f250583d28f332 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit meson

DESCRIPTION="A ncurses client for the Music Player Daemon (MPD)"
HOMEPAGE="https://www.musicpd.org/clients/ncmpc/ https://github.com/MusicPlayerDaemon/ncmpc"
SRC_URI="http://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"

LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="amd64 ~hppa ppc ppc64 ~sparc x86"
IUSE="+artist-screen async-connect chat-screen doc +help-screen key-screen lirc lyrics-screen outputs-screen search-screen +song-screen +mouse nls tcp"

RDEPEND="
	dev-libs/glib:2
	media-libs/libmpdclient
	sys-libs/ncurses:0=[unicode]
	lirc? ( app-misc/lirc )
"

DEPEND="
	${RDEPEND}
	doc? (
		app-doc/doxygen
		dev-python/sphinx
	)
	virtual/pkgconfig
"

DOCS=( doc/. AUTHORS README.rst )

src_prepare() {
	default
	sed -i -e '/'-Wl,--gc-sections'./d' meson.build || die "sed failed"
}

src_configure() {
	local emesonargs=(
		-Dcurses=ncursesw
		-Dcolors=true
		-Dmini=false
		-Dlyrics_plugin_dir="${EPREFIX}/usr/$(get_libdir)/ncmpc/lyrics"
		-Dartist_screen=$(usex artist-screen true false)
		-Dasync_connect=$(usex async-connect true false)
		-Dchat_screen=$(usex chat-screen true false)
		-Ddocumentation=$(usex doc true false)
		-Dhelp_screen=$(usex help-screen true false)
		-Dkey_screen=$(usex key-screen true false)
		-Dlyrics_screen=$(usex lyrics-screen true false)
		-Doutputs_screen=$(usex outputs-screen true false)
		-Dsearch_screen=$(usex search-screen true false)
		-Dsong_screen=$(usex song-screen true false)
		-Dlocale=$(usex nls true false)
		-Dmultibyte=$(usex nls true false)
		-Dnls=$(usex nls true false)
		-Dlirc=$(usex lirc true false)
		-Dmouse=$(usex mouse true false)
		-Dtcp=$(usex tcp true false)
		)
	meson_src_configure
}