blob: cb90134e49746ec9ac393f06ae94034de8c6135b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
|
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
inherit eutils gnome2-utils multilib flag-o-matic
MY_P=makemkv-oss-${PV}
MY_PB=makemkv-bin-${PV}
DESCRIPTION="Tool for ripping and streaming Blu-ray, HD-DVD and DVD discs"
HOMEPAGE="http://www.makemkv.com/"
SRC_URI="http://www.makemkv.com/download/${MY_P}.tar.gz
http://www.makemkv.com/download/${MY_PB}.tar.gz"
LICENSE="LGPL-2.1 MPL-1.1 MakeMKV-EULA openssl"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="libav multilib qt4 qt5"
REQUIRED_USE="?? ( qt4 qt5 )"
QA_PREBUILT="usr/bin/makemkvcon usr/bin/mmdtsdec"
DEPEND="
sys-libs/glibc[multilib?]
dev-libs/expat
dev-libs/openssl:0
sys-libs/zlib
qt4? (
dev-qt/qtcore:4
dev-qt/qtdbus:4
dev-qt/qtgui:4
)
qt5? (
dev-qt/qtcore:5
dev-qt/qtdbus:5
dev-qt/qtgui:5
dev-qt/qtwidgets:5
)
!libav? ( >=media-video/ffmpeg-1.0.0:0= )
libav? ( >=media-video/libav-0.8.9:0= )
"
RDEPEND="${DEPEND}
net-misc/wget"
# Upstream uses non-standard locale names so map them with this
# associative array and perform some tricks below.
declare -A MY_LOCALES
MY_LOCALES=(
[zh]=chi
[da]=dan
[de]=deu
[nl]=dut
[fr]=fra
[it]=ita
[ja]=jpn
[no]=nor
[fa]=per
[pl]=pol
[pt_BR]=ptb
[es]=spa
[sv]=swe
)
PLOCALES="${!MY_LOCALES[@]}"
inherit l10n
S="${WORKDIR}/makemkv-oss-${PV}"
src_prepare() {
PATCHES+=( "${FILESDIR}"/${PN}-{makefile,path,sysmacros}.patch )
# Qt5 always trumps Qt4 if it is available. There are no configure
# options or variables to control this and there is no publicly
# available configure.ac either.
if use qt4; then
PATCHES+=( "${FILESDIR}"/${PN}-qt4.patch )
elif use qt5; then
PATCHES+=( "${FILESDIR}"/${PN}-qt5.patch )
fi
# Check for locale changes against the non-standard names.
PLOCALES="${MY_LOCALES[@]}" l10n_find_plocales_changes "${WORKDIR}"/${MY_PB}/src/share makemkv_ .mo.gz
default
}
src_configure() {
# See bug #439380.
replace-flags -O* -Os
local econf_args=()
if use qt4 || use qt5; then
econf_args+=( '--enable-gui' )
else
econf_args+=( '--disable-gui' )
fi
econf "${econf_args[@]}"
}
src_compile() {
emake GCC="$(tc-getCC) ${CFLAGS} ${LDFLAGS}"
}
src_install() {
# install oss package
dolib.so out/libdriveio.so.0
dolib.so out/libmakemkv.so.1
dolib.so out/libmmbd.so.0
dosym libdriveio.so.0 /usr/$(get_libdir)/libdriveio.so.0.${PV}
dosym libdriveio.so.0 /usr/$(get_libdir)/libdriveio.so
dosym libmakemkv.so.1 /usr/$(get_libdir)/libmakemkv.so.1.${PV}
dosym libmakemkv.so.1 /usr/$(get_libdir)/libmakemkv.so
dosym libmmbd.so.0 /usr/$(get_libdir)/libmmbd.so
dosym libmmbd.so.0 /usr/$(get_libdir)/libmmbd.so.0.${PV}
if use qt4 || use qt5; then
dobin out/makemkv
local res
for res in 16 22 32 64 128; do
newicon -s ${res} makemkvgui/share/icons/${res}x${res}/makemkv.png ${PN}.png
done
make_desktop_entry ${PN} MakeMKV ${PN} 'Qt;AudioVideo;Video'
fi
cd "${WORKDIR}"/${MY_PB} || die
# install prebuilt bins
if use x86; then
dobin bin/i386/{makemkvcon,mmdtsdec}
elif use amd64; then
dobin bin/amd64/makemkvcon
use multilib && dobin bin/i386/mmdtsdec
fi
insinto /usr/share/MakeMKV
# install profiles
doins src/share/*.xml
# install locales
local locale
for locale in $(l10n_get_locales); do
doins src/share/makemkv_${MY_LOCALES[${locale}]}.mo.gz
done
}
pkg_preinst() { gnome2_icon_savelist; }
pkg_postinst() {
gnome2_icon_cache_update
elog "While MakeMKV is in beta mode, upstream has provided a license"
elog "to use if you do not want to purchase one."
elog ""
elog "See this forum thread for more information, including the key:"
elog "http://www.makemkv.com/forum2/viewtopic.php?f=5&t=1053"
elog ""
elog "Note that beta license may have an expiration date and you will"
elog "need to check for newer licenses/releases. "
elog ""
elog "We previously said to copy default.mmcp.xml to ~/.MakeMKV/. This"
elog "is no longer necessary and you should delete it from there to"
elog "avoid warning messages."
elog ""
elog "MakeMKV can also act as a drop-in replacement for libaacs and"
elog "libbdplus, allowing transparent decryption of a wider range of"
elog "titles under players like VLC and mplayer. To enable this, set"
elog "the following variables when launching the player:"
elog "LIBAACS_PATH=libmmbd LIBBDPLUS_PATH=libmmbd"
}
pkg_postrm() { gnome2_icon_cache_update; }
|
GitWeb