net-analyzer/prelude-correlator/prelude-correlator-5.2.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

PYTHON_COMPAT=( python3_{8..10} )

inherit distutils-r1 systemd tmpfiles

DESCRIPTION="Real time correlator of events received by Prelude Manager"
HOMEPAGE="https://www.prelude-siem.org"
SRC_URI="https://www.prelude-siem.org/pkg/src/${PV}/${P}.tar.gz"

LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~x86"

RDEPEND=">=dev-libs/libprelude-5.2.0[python,${PYTHON_USEDEP}]
	<dev-libs/libprelude-6[python,${PYTHON_USEDEP}]
	dev-python/netaddr[${PYTHON_USEDEP}]"

PATCHES=(
	"${FILESDIR}/${PN}-5.2.0-fix_siteconfig.patch"
)

src_install() {
	distutils-r1_src_install

	keepdir /var/${PN}
	keepdir /var/spool/prelude/prelude-correlator

	systemd_dounit "${FILESDIR}/${PN}.service"
	newtmpfiles "${FILESDIR}/${PN}.run" "${PN}.conf"

	newinitd "${FILESDIR}/${PN}.initd" "${PN}"
}

pkg_postinst() {
	tmpfiles_process ${PN}.conf
}