net-analyzer/ssldump/ssldump-1.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7
inherit multilib toolchain-funcs

DESCRIPTION="An SSLv3/TLS network protocol analyzer"
HOMEPAGE="https://github.com/adulau/ssldump/"
SRC_URI="
	https://github.com/adulau/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
"

LICENSE="openssl"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
IUSE="ssl"

RDEPEND="
	net-libs/libpcap
	ssl? ( >=dev-libs/openssl-1:0= )
"
DEPEND="
	${RDEPEND}
"

src_configure() {
	tc-export CC

	econf \
		$(usex ssl --with-openssl-inc="${EPREFIX}/usr/include" '') \
		$(usex ssl --with-openssl-lib="${EPREFIX}/usr/$(get_libdir)" '') \
		$(usex ssl --with-openssl="${EPREFIX}/usr") \
		--with-pcap-inc="${EPREFIX}/usr/include" \
		--with-pcap-lib="${EPREFIX}/usr/$(get_libdir)"
}

src_install() {
	dosbin ssldump
	doman ssldump.1
	dodoc ChangeLog CREDITS README
}