blob: 42cec5837e6b1aa74594e421e5d31352002ffd3c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
|
# Copyright 1999-2018 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=( python2_7 )
inherit cmake-utils python-single-r1 systemd user
DESCRIPTION="An open source instant messaging transport"
HOMEPAGE="https://www.spectrum.im"
SRC_URI="https://github.com/SpectrumIM/spectrum2/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64"
IUSE="debug doc frotz irc mysql postgres purple sms +sqlite test twitter whatsapp xmpp"
REQUIRED_USE="|| ( mysql postgres sqlite )"
RDEPEND="
dev-libs/boost:=
dev-libs/expat
dev-libs/log4cxx
dev-libs/jsoncpp:=
dev-libs/openssl:0=
dev-libs/popt
dev-libs/protobuf:=
net-dns/libidn:0=
net-misc/curl
sys-libs/zlib:=
frotz? ( !games-engines/frotz )
irc? ( net-im/libcommuni )
mysql? (
|| (
dev-db/mariadb-connector-c
dev-db/mysql-connector-c
)
)
postgres? ( dev-libs/libpqxx:= )
purple? (
dev-libs/glib
dev-libs/libev:=
net-im/pidgin:=
)
sms? ( app-mobilephone/smstools )
sqlite? ( dev-db/sqlite:3 )
twitter? ( net-misc/curl )
whatsapp? ( net-im/transwhat )
xmpp? ( net-im/swift:= )"
DEPEND="
${PYTHON_DEPS}
${RDEPEND}
doc? ( app-doc/doxygen )
test? (
dev-python/sleekxmpp[${PYTHON_USEDEP}]
dev-util/cppunit
net-irc/ngircd
)
"
PATCHES=(
"${FILESDIR}/${P}-remove_debug_cflags.patch"
"${FILESDIR}/${P}-use_qt5_libcommuni.patch"
)
# Tests are currently restricted, as they do completly fail
RESTRICT="test"
pkg_setup() {
enewgroup spectrum
enewuser spectrum -1 -1 /var/lib/spectrum2 spectrum
use test && python-single-r1_pkg_setup
}
src_prepare() {
# Respect users LDFLAGS
sed -i -e "s/-Wl,-export-dynamic/& ${LDFLAGS}/" spectrum/src/CMakeLists.txt || die
# Respect users CFLAGS, when compiling for debug mode
# Since Spectrum2 searches for a qt4 compiled libcommuni,
# it must be patched, to find the qt5 compiled libcommuni,
# See: https://github.com/SpectrumIM/spectrum2/pull/253
cmake-utils_src_prepare
}
src_configure() {
use debug && CMAKE_BUILD_TYPE="Debug"
local mycmakeargs=(
-DENABLE_DOCS="$(usex doc)"
-DENABLE_FROTZ="$(usex frotz)"
-DENABLE_IRC="$(usex irc)"
-DENABLE_MYSQL="$(usex mysql)"
-DENABLE_PQXX="$(usex postgres)"
-DENABLE_PURPLE="$(usex purple)"
-DENABLE_SMSTOOLS3="$(usex sms)"
-DENABLE_SQLITE3="$(usex sqlite)"
-DENABLE_TESTS="$(usex test)"
-DENABLE_TWITTER="$(usex twitter)"
-DENABLE_XMPP="$(usex xmpp)"
-DLIB_INSTALL_DIR="$(get_libdir)"
)
cmake-utils_src_configure
}
src_test() {
cd tests/libtransport && "${EPYTHON}" ../start.py || die
}
src_install() {
cmake-utils_src_install
diropts -o spectrum -g spectrum
keepdir /var/log/spectrum2 /var/lib/spectrum2
diropts
newinitd "${FILESDIR}"/spectrum2.initd spectrum2
systemd_newunit "${FILESDIR}"/spectrum2.service spectrum2.service
systemd_newtmpfilesd "${FILESDIR}"/spectrum2.tmpfiles spectrum2.conf
einstalldocs
}
|
GitWeb