blob: f95f3178e06cc0a212b3eb730f21f8c92e4b1c38 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Copyright 2022-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit go-module systemd
DESCRIPTION="soju is a user-friendly IRC bouncer"
HOMEPAGE="https://soju.im/"
SRC_URI="https://git.sr.ht/~emersion/${PN}/refs/download/v${PV}/${P}.tar.gz"
SRC_URI+=" https://github.com/alfredfo/${PN}-deps/raw/master/${P}-deps.tar.xz"
LICENSE="AGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~riscv"
IUSE="moderncsqlite +sqlite pam"
REQUIRED_USE="?? ( moderncsqlite sqlite )"
BDEPEND="
app-text/scdoc
"
RDEPEND="
acct-user/soju
acct-group/soju
sqlite? ( dev-db/sqlite:3 )
"
DEPEND="${RDEPEND}"
PATCHES=(
"${FILESDIR}"/${PN}-0.6.0-fix-dup-upstream-connections.patch
)
src_compile() {
if use sqlite; then
GOFLAGS+=" -tags=libsqlite3"
elif use moderncsqlite; then
GOFLAGS+=" -tags=moderncsqlite"
else
GOFLAGS+=" -tags=nosqlite"
fi
use pam && GOFLAGS+=" -tags=pam"
ego build ${GOFLAGS} ./cmd/soju
ego build ${GOFLAGS} ./cmd/sojudb
ego build ${GOFLAGS} ./cmd/sojuctl
scdoc <doc/soju.1.scd >doc/soju.1 || die
}
src_install() {
dobin soju
dobin sojudb
dobin sojuctl
doman doc/soju.1
systemd_dounit contrib/soju.service
keepdir /etc/soju
insinto /etc/soju
newins config.in config
newinitd "${FILESDIR}"/soju.initd soju
einstalldocs
}
pkg_postinst() {
elog "${PN} requires a user database for authenticating clients."
elog "As the soju user, create a database using:"
elog "$ sojudb -config ${EROOT}/etc/soju/config create-user <username> [-admin]"
}
|
GitWeb
