blob: e4306625c910e084cf0a2c48d776c995cf39adc2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit cmake
MY_PV="${PV//_pre/-pre}"
DESCRIPTION="Modern open source high performance RPC framework"
HOMEPAGE="https://www.grpc.io"
SRC_URI="https://github.com/${PN}/${PN}/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~ppc64 ~x86"
IUSE="doc examples test"
RDEPEND="
=dev-cpp/abseil-cpp-20200225*:=
dev-libs/re2:=
>=dev-libs/protobuf-3.13.0:=
>=net-dns/c-ares-1.15.0:=
sys-libs/zlib:=
>=dev-libs/openssl-1.1.1:0=[-bindist]
"
DEPEND="${RDEPEND}
test? (
dev-cpp/benchmark
dev-cpp/gflags
)
"
BDEPEND="virtual/pkgconfig"
# requires sources of many google tools
RESTRICT="test"
S="${WORKDIR}/${PN}-${MY_PV}"
PATCHES=( "${FILESDIR}/use-pkg-config-to-find-re2.patch" )
src_prepare() {
cmake_src_prepare
# un-hardcode libdir
sed -i "s@lib/pkgconfig@$(get_libdir)/pkgconfig@" CMakeLists.txt || die
sed -i "s@/lib@/$(get_libdir)@" cmake/pkg-config-template.pc.in || die
}
src_configure() {
local mycmakeargs=(
-DgRPC_INSTALL=ON
-DgRPC_ABSL_PROVIDER=package
-DgRPC_BACKWARDS_COMPATIBILITY_MODE=OFF
-DgRPC_CARES_PROVIDER=package
-DgRPC_INSTALL_CMAKEDIR="$(get_libdir)/cmake/${PN}"
-DgRPC_INSTALL_LIBDIR="$(get_libdir)"
-DgRPC_PROTOBUF_PROVIDER=package
-DgRPC_RE2_PROVIDER=package
-DgRPC_SSL_PROVIDER=package
-DgRPC_ZLIB_PROVIDER=package
-DgRPC_BUILD_TESTS=$(usex test)
$(usex test '-DgRPC_GFLAGS_PROVIDER=package' '')
$(usex test '-DgRPC_BENCHMARK_PROVIDER=package' '')
)
cmake_src_configure
}
src_install() {
cmake_src_install
if use examples; then
find examples -name '.gitignore' -delete || die
dodoc -r examples
docompress -x /usr/share/doc/${PF}/examples
fi
if use doc; then
find doc -name '.gitignore' -delete || die
local DOCS=( AUTHORS CONCEPTS.md README.md TROUBLESHOOTING.md doc/. )
fi
einstalldocs
}
|
GitWeb