blob: 71e771406fa3d7a7525d869a00f47c32e79513d4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit cmake-utils systemd user
MY_P="c-toxcore-${PV}"
DESCRIPTION="Encrypted P2P, messaging, and audio/video calling platform"
HOMEPAGE="https://tox.chat"
SRC_URI="https://github.com/TokTok/c-toxcore/archive/v${PV}.tar.gz -> ${MY_P}.tar.gz"
LICENSE="GPL-3+"
SLOT="0/0.2"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="+av daemon log-debug log-trace +no-log static-libs test"
REQUIRED_USE="^^ ( no-log log-trace log-debug )"
RDEPEND="
av? ( media-libs/libvpx:=
media-libs/opus )
daemon? ( dev-libs/libconfig )
>=dev-libs/libsodium-0.6.1:=[asm,urandom]"
DEPEND="${RDEPEND}
virtual/pkgconfig"
S="${WORKDIR}/${MY_P}"
src_prepare() {
cmake-utils_src_prepare
# disable tests that need internet
for testname in bootstrap lan_discovery tcp_relay tox_many_tcp; do
sed -i -e "/^auto_test(${testname})$/d" CMakeLists.txt || die
done
}
src_configure() {
local mycmakeargs=(
-DTRACE=$(usex log-trace)
-DDEBUG=$(usex log-debug)
-DBUILD_TOXAV=$(usex av)
-DMUST_BUILD_TOXAV=$(usex av)
-DBUILD_AV_TEST=$(usex av)
-DBOOTSTRAP_DAEMON=$(usex daemon)
-DENABLE_STATIC=$(usex static-libs)
)
cmake-utils_src_configure
}
src_install() {
cmake-utils_src_install
if use daemon; then
newinitd "${FILESDIR}"/initd tox-dht-daemon
newconfd "${FILESDIR}"/confd tox-dht-daemon
insinto /etc
doins "${FILESDIR}"/tox-bootstrapd.conf
systemd_dounit "${FILESDIR}"/tox-bootstrapd.service
fi
find "${D}" -name '*.la' -delete || die
}
pkg_postinst() {
if use daemon; then
enewgroup tox
enewuser tox -1 -1 -1 tox
if [[ -f ${EROOT%/}/var/lib/tox-dht-bootstrap/key ]]; then
ewarn "Backwards compatability with the bootstrap daemon might have been"
ewarn "broken a while ago. To resolve this issue, REMOVE the following files:"
ewarn " ${EROOT%/}/var/lib/tox-dht-bootstrap/key"
ewarn " ${EROOT%/}/etc/tox-bootstrapd.conf"
ewarn " ${EROOT%/}/run/tox-dht-bootstrap/tox-dht-bootstrap.pid"
ewarn "Then just re-emerge net-libs/tox"
fi
fi
}
|
GitWeb