blob: eb062590f36be59c22a0c2c986cd68dc60ca3b88 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit toolchain-funcs
DESCRIPTION="Collection of utilities for parsing Internet mail messages"
SRC_URI="http://cr.yp.to/software/${P}.tar.gz"
HOMEPAGE="http://cr.yp.to/mess822.html"
SLOT="0"
KEYWORDS="amd64 ppc x86"
IUSE=""
LICENSE="public-domain"
RDEPEND=">=sys-apps/sed-4"
DEPEND="${RDEPEND}"
RESTRICT="test"
PATCHES=(
"${FILESDIR}"/${P}-implicit.patch
)
src_prepare() {
default
echo "$(tc-getCC) ${CFLAGS}" > conf-cc
echo "$(tc-getCC) ${LDFLAGS}" > conf-ld
echo "/usr" > conf-home
# fix errno.h problem; bug #26165
sed -i 's/^extern int errno;/#include <errno.h>/' error.h || die
sed -i -e "s/ar/$(tc-getAR)/" make-makelib.sh || die
sed -i -e "s/ranlib/$(tc-getRANLIB)/" make-makelib.sh || die
}
src_install() {
dodir /etc
dodir /usr/share
# Now that the commands are compiled, update the conf-home file to point
# to the installation image directory.
echo "${ED}/usr/" > conf-home
sed -i -e "s:\"/etc\":\"${ED}/etc\":" hier.c || die "sed hier.c failed"
emake setup
# Move the man pages into /usr/share/man
mv "${ED}/usr/man" "${ED}/usr/share/" || die
dodir /usr/$(get_libdir)
mv "${ED}/usr/lib/${PN}.a" "${ED}/usr/$(get_libdir)/${PN}.a" || die
rmdir "${ED}/usr/lib" || die
dodoc BLURB CHANGES INSTALL README THANKS TODO VERSION
}
|
GitWeb
