blob: 6c9b293447188bad213be08c7cddfc7edbe67d62 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
|
# Copyright 2011-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake flag-o-matic
if [[ ${PV} == *9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/FreeRDP/FreeRDP.git"
case ${PV} in
2.*) EGIT_BRANCH="stable-2.0";;
esac
else
MY_P=${P/_/-}
S="${WORKDIR}/${MY_P}"
SRC_URI="https://pub.freerdp.com/releases/${MY_P}.tar.gz"
KEYWORDS="~alpha amd64 arm arm64 ~loong ppc ppc64 ~riscv x86"
fi
DESCRIPTION="Free implementation of the Remote Desktop Protocol"
HOMEPAGE="https://www.freerdp.com/"
LICENSE="Apache-2.0"
SLOT="2"
IUSE="alsa cpu_flags_arm_neon client cups debug +ffmpeg gstreamer icu jpeg kerberos openh264 pulseaudio server smartcard systemd test usb valgrind wayland X xinerama xv"
RESTRICT="!test? ( test )"
BDEPEND="
virtual/pkgconfig
app-text/docbook-xml-dtd:4.1.2
app-text/xmlto
"
COMMON_DEPEND="
dev-libs/openssl:0=
sys-libs/zlib:0
alsa? ( media-libs/alsa-lib )
cups? ( net-print/cups )
usb? (
virtual/libudev:0=
sys-apps/util-linux:0=
dev-libs/dbus-glib:0=
virtual/libusb:1=
)
X? (
x11-libs/libXcursor
x11-libs/libXext
x11-libs/libXi
x11-libs/libXrender
xinerama? ( x11-libs/libXinerama )
xv? ( x11-libs/libXv )
)
ffmpeg? ( media-video/ffmpeg:0= )
!ffmpeg? (
x11-libs/cairo:0=
)
gstreamer? (
media-libs/gstreamer:1.0
media-libs/gst-plugins-base:1.0
x11-libs/libXrandr
)
icu? ( dev-libs/icu:0= )
jpeg? ( media-libs/libjpeg-turbo:0= )
kerberos? ( virtual/krb5 )
openh264? ( media-libs/openh264:0= )
pulseaudio? ( media-libs/libpulse )
server? (
X? (
x11-libs/libXcursor
x11-libs/libXdamage
x11-libs/libXext
x11-libs/libXfixes
x11-libs/libXrandr
x11-libs/libXtst
xinerama? ( x11-libs/libXinerama )
)
)
smartcard? ( sys-apps/pcsc-lite )
systemd? ( sys-apps/systemd:0= )
client? (
wayland? (
dev-libs/wayland
x11-libs/libxkbcommon
)
)
X? (
x11-libs/libX11
x11-libs/libxkbfile
)
"
DEPEND="${COMMON_DEPEND}
valgrind? ( dev-debug/valgrind )
"
RDEPEND="${COMMON_DEPEND}
!net-misc/freerdp:0
client? ( !net-misc/freerdp:3[client] )
server? ( !net-misc/freerdp:3[server] )
"
src_prepare() {
local PATCHES=(
"${FILESDIR}/freerdp-2.11.2-clang.patch"
"${FILESDIR}/freerdp-2.11-Revert-codec-encode-messages-considering-endianness.patch"
)
cmake_src_prepare
}
option() {
usex "$1" ON OFF
}
option_client() {
if use client; then
option "$1"
else
echo OFF
fi
}
src_configure() {
# bug #881695
filter-lto
local mycmakeargs=(
-Wno-dev
-DBUILD_TESTING=$(option test)
-DCHANNEL_URBDRC=$(option usb)
-DWITH_ALSA=$(option alsa)
-DWITH_CCACHE=OFF
-DWITH_CUPS=$(option cups)
-DWITH_CLIENT=$(option client)
-DWITH_DEBUG_ALL=$(option debug)
-DWITH_MANPAGES=ON
-DWITH_FFMPEG=$(option ffmpeg)
-DWITH_SWSCALE=$(option ffmpeg)
-DWITH_CAIRO=$(option !ffmpeg)
-DWITH_DSP_FFMPEG=$(option ffmpeg)
-DWITH_GSTREAMER_1_0=$(option gstreamer)
-DWITH_ICU=$(option icu)
-DWITH_JPEG=$(option jpeg)
-DWITH_GSSAPI=$(option kerberos)
-DWITH_NEON=$(option cpu_flags_arm_neon)
-DWITH_OPENH264=$(option openh264)
-DWITH_OSS=OFF
-DWITH_PULSE=$(option pulseaudio)
-DWITH_SERVER=$(option server)
-DWITH_PCSC=$(option smartcard)
-DWITH_LIBSYSTEMD=$(option systemd)
-DWITH_VALGRIND_MEMCHECK=$(option valgrind)
-DWITH_X11=$(option X)
-DWITH_XINERAMA=$(option xinerama)
-DWITH_XV=$(option xv)
-DWITH_WAYLAND=$(option_client wayland)
-DWITH_WINPR_TOOLS=$(option server)
)
cmake_src_configure
}
src_test() {
local myctestargs=( -E TestBacktrace )
cmake_src_test
}
src_install() {
cmake_src_install
mv "${ED}"/usr/share/man/man7/wlog{,2}.7 || die
}
|
GitWeb