blob: 0336830c9e3d9059be66e946340419282aeebfb4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
|
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
inherit autotools cmake-utils eutils flag-o-matic java-pkg-opt-2
XSERVER_VERSION="1.17.4"
DESCRIPTION="Remote desktop viewer display system"
HOMEPAGE="http://www.tigervnc.org"
SRC_URI="https://github.com/TigerVNC/tigervnc/archive/v${PV}.tar.gz -> ${P}.tar.gz
mirror://gentoo/${PN}.png
https://dev.gentoo.org/~armin76/dist/tigervnc-1.4.2-patches-0.1.tar.bz2
server? ( ftp://ftp.freedesktop.org/pub/xorg/individual/xserver/xorg-server-${XSERVER_VERSION}.tar.bz2 )"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm hppa ~ia64 ~mips ~ppc ppc64 ~sh ~sparc ~x86"
IUSE="gnutls java +opengl pam server +xorgmodule"
RDEPEND="virtual/jpeg:0
sys-libs/zlib
>=x11-libs/libXtst-1.0.99.2
>=x11-libs/fltk-1.3.1
gnutls? ( net-libs/gnutls )
java? ( >=virtual/jre-1.5 )
pam? ( virtual/pam )
server? (
dev-lang/perl
>=x11-libs/libXi-1.2.99.1
>=x11-libs/libXfont-1.4.2
>=x11-libs/libxkbfile-1.0.4
x11-libs/libXrender
>=x11-libs/pixman-0.27.2
>=x11-apps/xauth-1.0.3
x11-apps/xsetroot
>=x11-misc/xkeyboard-config-2.4.1-r3
opengl? ( >=app-eselect/eselect-opengl-1.3.1-r1 )
xorgmodule? ( =x11-base/xorg-server-${XSERVER_VERSION%.*}* )
)
!net-misc/vnc
!net-misc/tightvnc
!net-misc/xf4vnc"
DEPEND="${RDEPEND}
amd64? ( dev-lang/nasm )
x86? ( dev-lang/nasm )
>=x11-proto/inputproto-2.2.99.1
>=x11-proto/xextproto-7.2.99.901
>=x11-proto/xproto-7.0.26
java? ( >=virtual/jdk-1.5 )
server? (
virtual/pkgconfig
media-fonts/font-util
x11-misc/util-macros
>=x11-proto/bigreqsproto-1.1.0
>=x11-proto/compositeproto-0.4
>=x11-proto/damageproto-1.1
>=x11-proto/fixesproto-5.0
>=x11-proto/fontsproto-2.1.3
>=x11-proto/glproto-1.4.17
>=x11-proto/randrproto-1.4.0
>=x11-proto/renderproto-0.11
>=x11-proto/resourceproto-1.2.0
>=x11-proto/scrnsaverproto-1.1
>=x11-proto/videoproto-2.2.2
>=x11-proto/xcmiscproto-1.2.0
>=x11-proto/xineramaproto-1.1.3
>=x11-libs/xtrans-1.3.3
>=x11-proto/dri2proto-2.8
opengl? ( >=media-libs/mesa-10.3.4-r1 )
)"
CMAKE_IN_SOURCE_BUILD=1
src_prepare() {
if use server ; then
cp -r "${WORKDIR}"/xorg-server-${XSERVER_VERSION}/. unix/xserver
fi
eapply "${WORKDIR}"/patches/010_libvnc-os.patch
eapply "${WORKDIR}"/patches/030_manpages.patch
eapply "${WORKDIR}"/patches/055_xstartup.patch
default
if use server ; then
cd unix/xserver || die
eapply ../xserver117.patch
eautoreconf
fi
}
src_configure() {
local mycmakeargs=(
-DENABLE_GNUTLS=$(usex gnutls)
-DENABLE_PAM=$(usex pam)
-DBUILD_JAVA=$(usex java)
)
cmake-utils_src_configure
if use server; then
cd unix/xserver || die
econf \
$(use_enable opengl glx) \
--disable-config-hal \
--disable-config-udev \
--disable-devel-docs \
--disable-dmx \
--disable-dri \
--disable-dri3 \
--disable-glamor \
--disable-kdrive \
--disable-libunwind \
--disable-linux-acpi \
--disable-record \
--disable-selective-werror \
--disable-silent-rules \
--disable-static \
--disable-tslib \
--disable-unit-tests \
--disable-xephyr \
--disable-xinerama \
--disable-xnest \
--disable-xorg \
--disable-xvfb \
--disable-xwin \
--disable-xwayland \
--enable-dri2 \
--with-pic \
--without-dtrace \
--disable-present \
--disable-unit-tests
fi
}
src_compile() {
cmake-utils_src_compile
use server && emake -C unix/xserver
}
src_install() {
cmake-utils_src_install
newicon "${DISTDIR}"/tigervnc.png vncviewer.png
make_desktop_entry vncviewer vncviewer vncviewer Network
if use server ; then
emake -C unix/xserver/hw/vnc DESTDIR="${D}" install
if ! use xorgmodule; then
rm -r "${D}"/usr/$(get_libdir)/xorg || die
else
rm "${D}"/usr/$(get_libdir)/xorg/modules/extensions/libvnc.la || die
fi
newconfd "${FILESDIR}"/${PN}.confd ${PN}
newinitd "${FILESDIR}"/${PN}.initd ${PN}
else
cd "${D}" || die
for f in vncserver vncpasswd x0vncserver vncconfig; do
rm usr/bin/$f || die
rm usr/share/man/man1/$f.1 || die
done
fi
}
|