blob: b64788d0b71b0b541e481b8cbaa21717a44d0a48 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake multibuild systemd xdg
DESCRIPTION="BitTorrent client in C++ and Qt"
HOMEPAGE="https://www.qbittorrent.org
https://github.com/qbittorrent"
if [[ ${PV} == *9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/${PN}/qBittorrent.git"
else
SRC_URI="https://github.com/qbittorrent/qBittorrent/archive/release-${PV}.tar.gz -> ${P}.tar.gz"
#KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
S="${WORKDIR}/qBittorrent-release-${PV}"
fi
LICENSE="GPL-2"
SLOT="0"
IUSE="+dbus +gui webui"
REQUIRED_USE="dbus? ( gui )"
RDEPEND="
>=dev-libs/boost-1.65.0-r1:=
dev-libs/openssl:=
dev-qt/qtcore:5
dev-qt/qtnetwork:5[ssl]
dev-qt/qtsql:5
dev-qt/qtxml:5
>=net-libs/libtorrent-rasterbar-1.2.14:=
sys-libs/zlib
dbus? ( dev-qt/qtdbus:5 )
gui? (
dev-libs/geoip
dev-qt/qtgui:5
dev-qt/qtsvg:5
dev-qt/qtwidgets:5
)"
DEPEND="${RDEPEND}"
BDEPEND="dev-qt/linguist-tools:5
virtual/pkgconfig"
DOCS=( AUTHORS Changelog CONTRIBUTING.md README.md TODO )
src_prepare() {
MULTIBUILD_VARIANTS=( base )
use gui && MULTIBUILD_VARIANTS+=( gui )
use webui && MULTIBUILD_VARIANTS+=( webui )
multibuild_foreach_variant cmake_src_prepare
}
src_configure() {
multibuild_src_configure() {
local mycmakeargs=(
-DDBUS=$(usex dbus)
# musl lacks execinfo.h
-DSTACKTRACE=$(usex !elibc_musl)
# We always want to install unit files
-DSYSTEMD=ON
-DSYSTEMD_SERVICES_INSTALL_DIR=$(systemd_get_systemunitdir)
# More verbose build logs are preferable for bug reports
-DVERBOSE_CONFIGURE=ON
# Not yet in ::gentoo
-DQT6=OFF
# We do these in multibuild, see bug #839531 for why
# Fedora has to do the same thing.
-DGUI=OFF
-DWEBUI=OFF
)
if [[ ${MULTIBUILD_VARIANT} != base ]] ; then
mycmakeargs+=( -D${MULTIBUILD_VARIANT^^}=$(usex ${MULTIBUILD_VARIANT}) )
fi
cmake_src_configure
}
multibuild_foreach_variant multibuild_src_configure
}
src_compile() {
multibuild_foreach_variant cmake_src_compile
}
src_install() {
multibuild_foreach_variant cmake_src_install
einstalldocs
}
|
GitWeb