sci-biology/cufflinks/cufflinks-2.2.1-r2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=6

inherit autotools flag-o-matic toolchain-funcs

DESCRIPTION="Transcript assembly and differential expression/regulation for RNA-Seq"
HOMEPAGE="http://cufflinks.cbcb.umd.edu/"
SRC_URI="http://cufflinks.cbcb.umd.edu/downloads/${P}.tar.gz"

SLOT="0"
LICENSE="Artistic"
IUSE="debug"
KEYWORDS="~amd64 ~x86"

DEPEND="sci-biology/samtools:0.1-legacy
	>=dev-libs/boost-1.59.0:=
	dev-cpp/eigen:3"
RDEPEND="${DEPEND}"

PATCHES=(
	"${FILESDIR}"/${P}-samtools-legacy.patch
	"${FILESDIR}"/${P}-flags.patch
)

src_prepare() {
	default
	eautoreconf
	append-cppflags $($(tc-getPKG_CONFIG) --cflags eigen3)
}

src_configure() {
	econf --disable-optim \
		--with-boost-libdir="${EPREFIX}/usr/$(get_libdir)/" \
		--with-bam="${EPREFIX}/usr/" \
		$(use_enable debug)
}