blob: d747b381043509ddb435f3e805d60635be8dd851 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI="5"
PYTHON_COMPAT=( python{2_7,3_4,3_5} )
DISTUTILS_OPTIONAL="1"
inherit flag-o-matic toolchain-funcs distutils-r1
DESCRIPTION="I2C tools for bus probing, chip dumping, EEPROM decoding, and more"
HOMEPAGE="http://www.lm-sensors.org/wiki/I2CTools"
SRC_URI="http://dl.lm-sensors.org/i2c-tools/releases/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 arm ~arm64 ~mips ~ppc ~ppc64 ~sparc x86"
IUSE="python"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
RDEPEND="!<sys-apps/lm_sensors-3
python? ( ${PYTHON_DEPS} )"
DEPEND="${RDEPEND}"
src_prepare() {
epatch "${FILESDIR}"/${PN}-3.1.1-python-3.patch #492632
use python && distutils-r1_src_prepare
}
src_configure() {
use python && distutils-r1_src_configure
}
src_compile() {
emake CC=$(tc-getCC) CFLAGS="${CFLAGS}"
emake -C eepromer CC=$(tc-getCC) CFLAGS="${CFLAGS} -I../include"
if use python ; then
cd py-smbus || die
append-cppflags -I../include
distutils-r1_src_compile
fi
}
src_install() {
emake install prefix="${D}"/usr
dosbin eepromer/eepro{g,m{,er}}
rm -rf "${D}"/usr/include # part of linux-headers
dodoc CHANGES README
local d
for d in eeprom eepromer ; do
docinto ${d}
dodoc ${d}/README*
done
if use python ; then
cd py-smbus || die
docinto py-smbus
dodoc README*
distutils-r1_src_install
fi
}
|
GitWeb
