blob: 1c40324980927048a96b0c266b134d62ca2d685d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/sed.asc
inherit flag-o-matic verify-sig
DESCRIPTION="Super-useful stream editor"
HOMEPAGE="http://sed.sourceforge.net/"
SRC_URI="mirror://gnu/sed/${P}.tar.xz"
SRC_URI+=" verify-sig? ( mirror://gnu/sed/${P}.tar.xz.sig )"
LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
IUSE="acl nls selinux static"
RDEPEND="
!static? (
acl? ( virtual/acl )
nls? ( virtual/libintl )
selinux? ( sys-libs/libselinux )
)
"
DEPEND="${RDEPEND}
static? (
acl? ( virtual/acl[static-libs(+)] )
nls? ( virtual/libintl[static-libs(+)] )
selinux? ( sys-libs/libselinux[static-libs(+)] )
)
"
BDEPEND="nls? ( sys-devel/gettext )
verify-sig? ( sec-keys/openpgp-keys-sed )"
src_configure() {
use static && append-ldflags -static
local myconf=(
--exec-prefix="${EPREFIX}"
$(use_enable acl)
$(use_enable nls)
$(use_with selinux)
# rename to gsed for better BSD compatibility
--program-prefix=g
)
econf "${myconf[@]}"
}
src_install() {
default
# symlink to the standard name
dosym gsed /bin/sed
dosym gsed.1 /usr/share/man/man1/sed.1
}
|
GitWeb
