blob: bb76d9a19d3375fdede62e5ce256f047346fda9e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{8,9} )
inherit toolchain-funcs linux-info python-r1
DESCRIPTION="utility to checkpoint/restore a process tree"
HOMEPAGE="https://criu.org/"
SRC_URI="https://download.openvz.org/criu/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc64"
IUSE="doc selinux setproctitle static-libs"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
RDEPEND="
${PYTHON_DEPS}
>=dev-libs/protobuf-c-1.4.0:=
dev-libs/libnl:3
net-libs/libnet:1.1
sys-libs/libcap
selinux? ( sys-libs/libselinux )
setproctitle? ( dev-libs/libbsd )"
DEPEND="${RDEPEND}"
BDEPEND="
doc? (
app-text/asciidoc
app-text/xmlto
)"
RDEPEND="${RDEPEND}
dev-python/protobuf-python[${PYTHON_USEDEP}]"
CONFIG_CHECK="~CHECKPOINT_RESTORE ~NAMESPACES ~PID_NS ~FHANDLE ~EVENTFD ~EPOLL ~INOTIFY_USER
~UNIX_DIAG ~INET_DIAG ~INET_UDP_DIAG ~PACKET_DIAG ~NETLINK_DIAG ~TUN ~NETFILTER_XT_MARK"
# root access required for tests
RESTRICT="test"
PATCHES=(
"${FILESDIR}"/2.2/${PN}-2.2-flags.patch
"${FILESDIR}"/2.3/${PN}-2.3-no-git.patch
"${FILESDIR}"/${PN}-3.12-automagic-libbsd.patch
"${FILESDIR}"/${PN}-3.15-pkg-config.patch
"${FILESDIR}"/${PN}-3.15-protobuf-c-1.4.0.patch
)
criu_arch() {
# criu infers the arch from $(uname -m). We never want this to happen.
case ${ARCH} in
amd64) echo "x86";;
arm64) echo "aarch64";;
ppc64*) echo "ppc64";;
*) echo "${ARCH}";;
esac
}
pkg_setup() {
use amd64 && CONFIG_CHECK+=" ~IA32_EMULATION"
linux-info_pkg_setup
}
src_prepare() {
default
if ! use selinux; then
sed \
-e 's:libselinux:no_libselinux:g' \
-i Makefile.config || die
fi
use doc || sed -i 's_\(install: \)install-man _\1_g' Makefile.install
}
src_configure() {
# Gold linker generates invalid object file when used with criu's custom
# linker script. Use the bfd linker instead. See https://crbug.com/839665#c3
tc-ld-disable-gold
# Build system uses this variable as a trigger to append coverage flags
# we'd like to avoid it. https://bugs.gentoo.org/744244
unset GCOV
python_setup
}
src_compile() {
local target="all $(usex doc 'docs' '')"
emake \
HOSTCC="$(tc-getBUILD_CC)" \
CC="$(tc-getCC)" \
LD="$(tc-getLD)" \
AR="$(tc-getAR)" \
PKG_CONFIG="$(tc-getPKG_CONFIG)" \
PYTHON="${EPYTHON%.?}" \
FULL_PYTHON="${PYTHON%.?}" \
OBJCOPY="$(tc-getOBJCOPY)" \
LIBDIR="${EPREFIX}/usr/$(get_libdir)" \
ARCH="$(criu_arch)" \
V=1 WERROR=0 DEBUG=0 \
SETPROCTITLE=$(usex setproctitle) \
${target}
}
src_test() {
# root privileges are required to dump all necessary info
if [[ ${EUID} -eq 0 ]] ; then
emake -j1 CC="$(tc-getCC)" ARCH="$(criu_arch)" V=1 WERROR=0 test
fi
}
install_crit() {
"${EPYTHON}" scripts/crit-setup.py install --root="${D}" --prefix="${EPREFIX}/usr/" || die
python_optimize
}
src_install() {
emake \
ARCH="$(criu_arch)" \
PREFIX="${EPREFIX}"/usr \
PYTHON="${EPYTHON%.?}" \
FULL_PYTHON="${PYTHON%.?}" \
LOGROTATEDIR="${EPREFIX}"/etc/logrotate.d \
DESTDIR="${D}" \
LIBDIR="${EPREFIX}/usr/$(get_libdir)" \
V=1 WERROR=0 DEBUG=0 \
install
use doc && dodoc CREDITS README.md
python_foreach_impl install_crit
if ! use static-libs; then
find "${D}" -name "*.a" -delete || die
fi
}
|
GitWeb